Opmerkingen met.Range invoeren

[DutchOirs]

Goedemiddag allen,

Zit weer met een vraagje voor de Die-Hards.

Wil in 2 cellen een opmerking invoeren achter elkaar.

Maar helaas dat lukt niet, geeft foutmelding: Fout 91 tijdens uitvoering: Objectvariabele of blokvariabele With is niet ingesteld


Als ik er eentje invoer geen probleem, maar zo gauw de tweede erbij komt krijg ik die foutmelding.

  Dim i As Integer                  ' nb: als er niets in een comment staat werkt het niet!
  i = 5

  
  With Worksheets("Blad1")
    .Range("A" & i).Activate
    On Error GoTo nocomment1
    If .Range("A" & i).Comment.Text <> "" Then MsgBox "Cell 1 heeft al een comment": Exit Sub
nocomment1:
    .Range("A" & i).AddComment
    .Range("A" & i).Comment.Text Text:=vbNewLine & " Formule in deze cel" & vbNewLine & " is aangepast i.v.m." & vbNewLine & " de andere maanden"
    
    .Range("A" & i + 1).Activate
    On Error GoTo nocomment2
    If .Range("A" & i + 1).Comment.Text <> "" Then MsgBox "Cell 2 heeft al een comment": Exit Sub
nocomment2:
     .Range("A" & i + 1).AddComment
    .Range("A" & i + 1).Comment.Text Text:=vbNewLine & " Formule in deze cel" & vbNewLine & " is aangepast i.v.m." & vbNewLine & " de andere maanden"
  End With

Iemand een idee hierover?

Heb een vb-tje bijgevoegd.

Many thanks already.

Vr. Gr.

Dutch

 

[VenA]

Zo beter?

Private Sub StartKnop_Click()
Dim i As Integer                  ' nb: als er niets in een comment staat werkt het niet!
With Worksheets("Blad1")
  For i = 5 To 6
    If Not .Range("A" & i).Comment Is Nothing Then
      MsgBox "Cell " & i - 4 & " heeft al een comment"
     Else
      .Range("A" & i).AddComment Text:=vbNewLine & " Formule in deze cel" & vbNewLine & " is aangepast i.v.m." & vbNewLine & " de andere maanden"
    End If
  Next i
End With
End Sub

 

[DutchOirs]

Goedenavond VenA,

Thanks voor het meedenken, maar is het niet helemaal.

Probleem is de variabele i. Gebruikte in het voorbeeld 5 & 6, maar kan ook een ander getal zijn, vandaar de variabele.
Dat die 2e Comment niet wil heeft iets met het Comment te maken.
Van alles al geprobeerd

Eerst de een apart en dan de andere apart of eerst de andere apart en dan de een apart. Werkt allemaal, maar zo gauw je ze achter elkaar doet gaat het fout.

 

[VenA]

Eigenlijk heb ik niet echt een idee van wat je wilt. Rare constructie met de Exit Sub waardoor je mogelijk niet bij de juiste cel komt of mogelijk een bewuste keuze? On Error GoTo begrijp ik ook niet. Je springt dan naar een volgende procedure die waarschijnlijk de voorgaande niet meer 'snapt'.

Mogelijk zoiets

Private Sub StartKnop_Click()
Dim i As Integer ' nb: als er niets in een comment staat werkt het niet!
i = 5
With Worksheets("Blad1")
  If Not .Range("A" & i).Comment Is Nothing Then
    MsgBox "Cell " & i - 4 & " heeft al een comment"
      Else
      .Range("A" & i).AddComment vbNewLine & " Formule in deze cel" & vbNewLine & " is aangepast i.v.m." & vbNewLine & " de andere maanden"
    End If
    If Not .Range("A" & i + 1).Comment Is Nothing Then
    MsgBox "Cell " & i - 3 & " heeft al een comment"
      Else
      .Range("A" & i + 1).AddComment vbNewLine & " Formule in deze cel" & vbNewLine & " is aangepast i.v.m." & vbNewLine & " de andere maanden"
    End If
End With
End Sub

 

[DutchOirs]

Hoi VenA,

Dit is eigenlijk een beetje vervolg op vorige week om de formule in een cel te veranderen.

Dat werkt nu prima, alleen voor te waarschuwen (luxe) komt er dan een opmerking in de cel aan te hangen.

En dat is dit gebeuren. Als er al een comment in de cel zit dan gaat ie Exit sub, dat is met opzet gekozen.

 

[VenA]

Verklaar u nader. Een bestand van vorige week? Welke formules? Na de exit sub stopt toch de hele procedure?

 

[DutchOirs]

Hoi VenA,

ff je laatste getest en het werkt

In Test4 staat je laatste..

Thanks

Vr. Gr.

Dutch

 

[DutchOirs]

Verklaar u nader. Een bestand van vorige week? Welke formules? Na de exit sub stopt toch de hele procedure?

ff opgezocht en had het al veranderd naar Goto zie ik.. het geheel nog niet helemaal af omdat ik tegen dit huidige probleem op liep..

maar ook dat is weer opgelost.

Trouwens een betere dan dat activate, alleen .range is het mooist..

Thanks

ps. dit was van vorige week van Edmoor http://www.helpmij.nl/forum/showthr...e-in-cel-zetten-met-VBA?p=5917847#post5917847