Optellen kolommen tot en met bepaalde waarde

[pieterteunissen]

Ik heb een optelprobleem in Bekijk bijlage TEST.xlsxexcel.
Wellicht een bijzonder simpele oplossing, maar ik worstel er nu al zo lang mee dat ik door de bomen het bos niet meer zie.
Graag jullie hulp!

Ik heb twee tabellen waar ik mee moet rekenen.
Tabel Werkelijk geeft de werkelijke uitgaven weer.
Tabel budget geeft logischerwijs het budget weer en dat is reeds voor het hele jaar vastgesteld.

H8 tot en met H11 zijn de cumulatieve totalen van de werkelijkheid.

B4 moet handmatig ingevuld worden en J8 tot en met J11 moet dan uitgerekend worden.
als in B4 een 5 wordt ingevuld (of "mei", dat maakt niet zoveel uit), dan moet in J8 het resultaat van som b19:f19 gegeven worden (=284)

als in B4 een 2, of "feb", wordt ingevuld dan is het natuurlijk 116.
ik kan alleen geen formule bedenken/vinden voor J8 tot en met J11.

Wie kan me hiermee helpen?

 

[AlexCEL]

Als je de periode boven het budget 1 t/m 12 noemt i.p.v. jan-dec, dan kan de volgende formule helpen in J8:

=SOM.ALS($B$18:$M$18;"<="&$B$4;B19:M19)

 

[pieterteunissen]

Bedankt voor de tip.
Die werkt inderdaad.

Ik zie in de formule trouwens dat de verwijzingen op regelniveau gemaakt zijn.
Is het ook mogelijk om een verwijzing met formules erin te maken voor de locatie?
Voor het geval dat de locaties van budget in een andere volgorde staan als die bij werkelijk?

Het daadwerkelijke bestand waar ik mee moet werken bestaat namelijk uit een paar honderd regels, en het zou natuurlijk kunnen zijn dat die voor budget en werkelijkheid niet in dezelfde volgorde staan.

 

[AlexCEL]

Dat kan, bijvoorbeeld zo:

=SOMPRODUCT(($A$19:$A$22=A8)*($B$18:$M$18<=$B$4)*($B$19:$M$22))

Of alternatief:

=SOM.ALS($B$18:$M$18;"<="&$B$4;VERSCHUIVING($B$19:$M$19;VERGELIJKEN($A8;$A$19:$A$22;0)-1;0))

En mocht je toch de maandnamen zoals in je voorbeeld erboven willen houden:

=SOMPRODUCT(($A$19:$A$22=$A8)*(VERGELIJKEN($B$18:$M$18;{"jan";"feb";"mrt";"[COLOR="#FF0000"]april[/COLOR]";"mei";"jun";"jul";"aug";"sep";"okt";"nov";"dec"};0)<=$B$4)*($B$19:$M$22))

 

[pieterteunissen]

bedankt voor de tips.
ik krijg in het voorbeeld de eerste twee formules voor elkaar, dus daar kon ik mee uit de voeten.

Nu heb ik de formules ook in het echte bestand geplaatst en daar loop ik wat tegen problemen aan. Wat daar specifiek aan de hand is, is dat het budget op een ander tabblad staat en dat de office versie waar ik mee werk in het engels is.
de formule die ik " vertaald" en aangepast heb is de volgende:

Code:
=SUMPRODUCT(('Budget 2016'!$B$7:$B$44=J9)*('Budget 2016'!$E$5:$P$5<=$K$4)*('Budget 2016'!$E$7:$P$45))


Alternatief:
=SUMIF('Budget 2016'!$E$5:$P$5;"<="&$K$4;OFFSET('Budget 2016'!$E$7:$P$45;MATCH($J8;'Budget 2016'!$B$5:$B$45;0)-1;0))


Doe ik iets fout?
Of kan de formule niet over meerdere tabbladen heen wellicht?

 

[AlexCEL]

Hier een bestandje met alle formules erin, dan gaat de vertaling automatisch.

Bekijk bijlage TEST (AC).xlsx

Werken met tabbladen zou geen probleem moeten zijn.

 

[pieterteunissen]

ontzettend bedankt.
Hier zou ik mee uit de voeten moeten kunnen. Ga het vanavond uitgebreid testen!

 

[pieterteunissen]

alles getest en het werkt prima.
ontzettend bedankt voor de hulp!

 

[AlexCEL]

Mooi zo. Dan mag de vraag dus op "opgelost" gezet worden (rechtsbovenaan de pagina).