Optionbutton toevoegen in Userform

[Jhon van der Bo]

Ik heb een userform met daarin 2 optionbuttons. Option 1 heeft als creteria '<= 50', en optie 2 '<> 75'. Ik wil hier nu een 3de optie aan toevoegen. Deze 3de optie is verder gelijk aan 1 en 2 ALLEEN de creteria moet zijn 'INC, NS en 100'.
Zie anders ook 'bepaalde regels / kolommen kopieren' (met dank aan Ingrid voor deze code).

'*******************
Private Sub CmdWeergeven_Click()
If Not (OptionButton1.Value Or OptionButton2.Value) Then
MsgBox "Geen selectie gemaakt"
Else
weergeven
End If
Unload Me
End Sub



Sub weergeven()
Dim r As Long, laatste As Long
Range("C:C,I:I,Q:Q,S:S,T:T,W:W,AA:AA,AE:AE").Copy
Workbooks.Add
ActiveSheet.Paste
Range("A1").Select
laatste = Range("H65536").End(xlUp).Row

If OptionButton1.Value Then
For r = laatste To 3 Step -1
If IsNumeric(Cells(r, 8)) Then
If Not (Cells(r, 8) <= 50) Then Rows(r).Delete
Else
Rows(r).Delete
End If
Next r
Else
For r = laatste To 3 Step -1
If IsNumeric(Cells(r, 8)) Then
If Cells(r, 8) <> 75 Then Rows(r).Delete
Else
Rows(r).Delete
End If
Next r
End If
End Sub

'*******************

 

[Ingrid B]

Met volgende code zou het moeten lukken (ook in Excel 97)

Private Sub CmdWeergeven_Click()
  If Not (OptionButton1 Or OptionButton2 Or OptionButton3) Then
    MsgBox "Geen selectie gemaakt"
  Else
    weergeven
  End If
  Unload Me
End Sub

Sub weergeven()
Dim r As Long, laatste As Long
  Range("C:C,I:I,Q:Q,S:S,T:T,W:W,AA:AA,AE:AE").Copy
  Workbooks.Add
  ActiveSheet.Paste
  Range("A1").Select
  laatste = Range("H65536").End(xlUp).Row
  If OptionButton1 Then
    For r = laatste To 3 Step -1
      If IsNumeric(Cells(r, 8)) Then
        If Not (Cells(r, 8) <= 50) Then Rows(r).Delete
      Else
        Rows(r).Delete
      End If
    Next r
  ElseIf OptionButton2 Then
    For r = laatste To 3 Step -1
      If IsNumeric(Cells(r, 8)) Then
        If Cells(r, 8) <> 75 Then Rows(r).Delete
      Else
        Rows(r).Delete
      End If
    Next r
  Else
    For r = laatste To 3 Step -1
      If Not (Cells(r, 8) = "INC" Or Cells(r, 8) = "NS") Then
        If Cells(r, 8) <> 100 Then Rows(r).Delete
      End If
    Next r
  End If
End Sub

 

[Jhon van der Bo]

Werkt correct. :thumb:

Ingrid, Bedankt.

Jhon