PDF Opslaan

[HWV]

Sub Mail1_Every_Worksheet()
[COLOR="#FF0000"]Sheets(2).ExportAsFixedFormat 0, Environ("temp") & "\" & " Klachten nr. " & frmFormulier.klachtennummer & " " & frmFormulier.KlantNaam & " " & frmFormulier.Postcode & " " & frmFormulier.Plaats & " debnr. " & frmFormulier.AdresNummer & " " & Date & ".pdf"[/COLOR]
With CreateObject("Outlook.Application").CreateItem(0)
        .To = frmFormulier.VerzendEmailadres1
        .CC = frmFormulier.VerzendEmailadres2
        .Subject = "Klachten nr. " & frmFormulier.klachtennummer & " " & frmFormulier.KlantNaam & " " & frmFormulier.Postcode & " " & frmFormulier.Plaats & " debnr. " & frmFormulier.AdresNummer & " " & Date & ""
        .Body = "Betreft klachtennummer: " & frmFormulier.klachtennummer & " " & vbCrLf & "" & vbCrLf & "Beste collega, " & vbCrLf & "" & vbCrLf & "Er is een klacht geregistreerd op naam van: " & frmFormulier.KlantNaam & "" & vbCrLf & "De status van deze klacht is in behandeling bij: " & frmFormulier.Afgehandeld & "" & vbCrLf & "" & vbCrLf & "Met vriendelijke groet, " & vbCrLf & " Naam van bedrijf "
        .Attachments.Add Environ("temp") & "\" & " Klachten nr. " & frmFormulier.klachtennummer & " " & frmFormulier.KlantNaam & " " & frmFormulier.Postcode & " " & frmFormulier.Plaats & " debnr. " & frmFormulier.AdresNummer & " " & Date & ".pdf"
        .send 'Display
       End With
 [COLOR="#FF0000"]Kill Environ("temp") & "\" & " Klachten nr. " & frmFormulier.klachtennummer & " " & frmFormulier.KlantNaam & " " & frmFormulier.Postcode & " " & frmFormulier.Plaats & " debnr. " & frmFormulier.AdresNummer & " " & Date & ".pdf"[/COLOR]MsgBox ("Uw mail is verzonden!")
End Sub

Bovenstaande code gebruik om een pdf mail te verzenden, met een bepaalde tekst in de body.

Hij slaat deze op en daarna verwijderd hij deze.
Wat ik eigenlijk wil is dat hij hem opslaat niet in de temp maar op P:\Ingevulde bonnen\Klachten\
en dan is de kill ook niet meer nodig, verschillende dingen geprobeerd maar loop vast.

Iemand een idee !

HWV

 

[edmoor]

Sheets(2).ExportAsFixedFormat 0, "P:\Ingevulde bonnen\Klachten\" & " Klachten nr. " & frmFormulier.klachtennummer & " " & frmFormulier.KlantNaam & " " & frmFormulier.Postcode & " " & frmFormulier.Plaats & " debnr. " & frmFormulier.AdresNummer & " " & Date & ".pdf"

En qua leesbaarheid kan je dat dan beter zo schrijven:

Sheets(2).ExportAsFixedFormat 0, _
    "P:\Ingevulde bonnen\Klachten\" & _
    "Klachten nr. " & _
    frmFormulier.klachtennummer & _
    " " & _
    frmFormulier.KlantNaam & _
    " " & _
    frmFormulier.Postcode & _
    " " & _
    frmFormulier.Plaats & _
    " debnr. " & _
    frmFormulier.AdresNummer & _
    " " & _
    Date & _
    ".pdf"

Zo kan je dat met de andere erg lange regels ook doen. Zelf zou ik er zoiets van maken:

Sub Mail1_Every_Worksheet()
    Dim sPDF As String
    Dim sPAD As String
    Dim sBDY As String
    
    sPAD = "P:\Ingevulde bonnen\Klachten\"
    sPDF = "Klachten nr. " & _
           frmFormulier.klachtennummer & " " & _
           frmFormulier.KlantNaam & " " & _
           frmFormulier.Postcode & " " & _
           frmFormulier.Plaats & " debnr. " & _
           frmFormulier.AdresNummer & " " & _
           Date & ".pdf"
    
    sBDY = "Betreft klachtennummer: " & _
           frmFormulier.klachtennummer & vbCrLf & _
           "Beste collega, " & vbCrLf & vbCrLf & _
           "Er is een klacht geregistreerd op naam van: " & _
           frmFormulier.KlantNaam & vbCrLf & _
           "De status van deze klacht is in behandeling bij: " & _
           frmFormulier.Afgehandeld & vbCrLf & vbCrLf & _
           "Met vriendelijke groet, " & vbCrLf & _
           " Naam van bedrijf "
    
    Sheets(2).ExportAsFixedFormat 0, sPAD & sPDF
    With CreateObject("Outlook.Application").CreateItem(0)
        .To = frmFormulier.VerzendEmailadres1
        .CC = frmFormulier.VerzendEmailadres2
        .Subject = sPDF
        .Body = sBDY
        .Attachments.Add sPAD & sPDF
        .send 'Display
    End With
End Sub

 

[snb]

Als de macro in de macromodule van het userform 'frmformulier' staat is dit voldoende:

Sub Mail1_Every_Worksheet()
   c00= join(array("P:\Ingevulde bonnen\Klachten\Klachten nr. ", klachtennummer, KlantNaam,postcode,plaats,"debnr",adresnummer,date)) & ".pdf"

   Sheets(2).ExportAsFixedFormat 0, c00
   With CreateObject("Outlook.Application").CreateItem(0)
        .To = VerzendEmailadres1
        .CC = VerzendEmailadres2
        .Subject = replace(mid(c00,30),".pdf","")
        .Body = replace("Betreft klachtennummer: " & klachtennummer & "~~Beste collega, ~~Er is een klacht geregistreerd op naam van: " & KlantNaam & "~De status van deze klacht is in behandeling bij: " & Afgehandeld & "~~Met vriendelijke groet, ~Naam van bedrijf","~",vblf)
        .Attachments.Add c00
        .send
   End With
End Sub

 

[HWV]

Geweldig

Bedankt voor de input allemaal.
Ik had deze code in een module staan, nu gezet achter 'frmformulier'

Weer een stap verder

HWV