Personeelsnummers opzoeken met Do Loop??

[vriese1]

Hoi,

Ik wil het volgende met een VBA code doen:

In werkblad "Input" staat in kolom A een personeelsnummer, in kolom B de naam etc.
Vanaf rij 3 t/m rij 271

Ik wil:
- in werkblad "Resultaat" in cel $B$5 het eerste personeelsnummer krijgen
- dan de formules in het werkblad "Resultaat" laten doorrekenen
- dan het werkblad exporteren naar apart bestand (met naam: personeelsnummer en naam (de naam van de werknemer staat in cel B6 van werkblad "Resultaat") en dan plakken waarden.
- terug naar originele bestand

Vervolgens door naar het volgende personeelsnummer in werkbblad Input en dan weer hetzelfde als hierboven. Dit zou gemakkelijk moeten zijn met een Do Loop functie of een For Next??

Ik kom er niet uit!!

Wie wil mij helpen?

Alvast bedankt.

Groeten,
Emilio

 

[Haaren101]

Hallo Emilio,

zet hier eens een (opgeschoond, zonder prive gegevens) voorbeeldje. Dat praat een stuk makkelijker

Ron

 

[vriese1]

Hoi,

Bij deze het opgeschoonde bestandje om e.e.a. te verduidelijken.
Alvast bedankt.

Groeten,
Emilio

 

[Wigi]

Hier is volledige code:

Sub emiliovriese()

    Dim r As Range
    Dim wsInput As Worksheet
    Dim wsRes As Worksheet
    
    Set wsInput = Sheets("Input")
    Set wsRes = Sheets("Resultaat")
    
    For Each r In wsInput.Range("A3:A" & wsInput.Range("A" & Rows.Count).End(xlUp).Row)
    
        If Len(r.Value) Then
        
            With wsRes
                .Range("B5").Value = r.Value
                .Copy
            End With
            
            With ActiveSheet
                .Cells.Copy
                .Range("A1").PasteSpecial xlValues
                .Parent.SaveAs "C:\" & r.Value & " - " & .Range("B6").Value
                .Parent.Close
            End With
        
        End If
    
    Next
    
    MsgBox "klaar", vbInformation

End Sub

Wigi

 

[vriese1]

Opgelost!

Hi Wigi,

Thnx very much! Mijn vraag is met deze code opgelost. Super bedankt. :thumb:

Groeten,
Emilio