Plaatsen in de regio tellen

[robdgr]

In bijgaand bestand (een voorbeeld) staat in kolom A een naam, een komma en een plaatsnaam. In een hulpkolom (B) tel ik het aantal plaatsen dat in deze regio valt. In D1 zie je mijn poging om die hulpkolom niet te hoeven gebruiken, maar ik krijg geen werkende formule.

Kan dit eigenlijk wel? In het werkelijke bestand staan 141 vermeldingen, die hieraan voldoen.

 

[Cobbe]

Kijk eens of je hier iets kunt uithalen

Cobbe

 

[danny147]

Beste rdg1314

Misschien met de volgende formule werken en aanpassen.

=RECHTS(A1;LENGTE(A1)-VIND.ALLES(", ";A1)-1)

Dit geeft Leusden weer en dan vert.zoeken.

Groetjes Danny. :thumb:

 

[robdgr]

Cobbe,

Dank voor je reactie. Die splitsing had ik ook al aan gedacht, maar er staan op meer posities komma's. In het oorspronkelijke bestand staan plaatsnamen wel met hoofdletters.

 

[snb]

=aantal.als(i2:i26;links(deel(a1;vind.spec(" ";a1)+1;200);vind.spec(deel(a1;vind.spec(" ";a1)+1;200))-1))

 

[robdgr]

snb,

Deze geeft me een foutmelding. Ik denk dat ik mijn hulpkolom met

=ALS(ISFOUT(VIND.SPEC(",";A1;1));"";ALS(ISFOUT(VERT.ZOEKEN((RECHTS(A1;LENGTE(A1)-VIND.SPEC(",";A1;1)-1));I$2:I$26;1;0));0;1))

maar handhaaf. Deze geeft me een 1 als de plaatsnaam voorkomt en een 0 als dat niet het geval is. Die kolom tel ik op.

 

[Wigi]

Ha die Rob,

=SOMPRODUCT((ISTEKST(A1:A5))*(AANTAL.ALS(I2:I26;RECHTS(A1:A5;LENGTE(A1:A5)-VIND.SPEC(",";A1:A5;1)-1))))

Wigi

 

[robdgr]

Hoi Wigi,

Wederom dank, ik had hem niet zelf kunnen bedenken. In mijn oorspronkelijke bestand had ik hem omgebouwd tot

="Aantal reacties in deze regio: "&SOMPRODUCT((ISTEKST(A633:A846))*(AANTAL.ALS(Regio;RECHTS(A633:A846;LENGTE(A633:A846)-VIND.SPEC(",";A633:A846;1)-1))))

Uiteindelijk heb ik de tekst naar de celeigenschappen overgebracht, zodat ik een getal overhoud.