printen vanuit pagina zonder deze te openen

[Bakkerbakgraag]

Hallo allemaal,
ik heb een ogenschijnlijk simpel probleem, maar toch kom ik er niet uit.

1.Ik heb een tabblad (blad 1) dat een bepaald aantal malen wordt afgedrukt dmv van een variabele.
2.Er wordt een ander tabblad (blad 2) afgedrukt als bij punt 1.

Punt 1 werkt prima, punt 2 print wel, maar daar wil ik graag het volgende: Is het mogelijk
dat blad twee wordt afgedrukt zonder dat deze geopend wordt? M.a.w. blad 2 wordt niet
zichtbaar op het scherm maar wel geprint.

Is het tevens mogelijk om automatisch eerst het pop-up venster van de printer te openen voordat de
printopdracht start. Dit om eerst eventueel enkelzijdig/ dubbelzijdig, kleur/ geen kleur etc.in te stellen
voordat er geprint wordt?


Dit is de code die ik heb:

Sub printen()
For i = 1 To [a4] 
    With Sheets("blad1") 
    .[A2] = i 
    .PrintOut
    End With
Next i
 Sheets("Blad2").Select
    ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
        IgnorePrintAreas:=False
End Sub

Bij voorbaat dank!
Ramon

 

[Bakkerbakgraag]

Dank je wel voor je snelle reactie SjonR,

Ik heb de code aangepast zodat de printerinstellingen verschijnen voordat de eerste printopdracht wordt gegeven:

Sub printen()
Application.Dialogs(xlDialogPrint).Show
For i = 1 To [a4]
With Sheets("blad1")
.[A2] = i
.PrintOut
End With
Next i

Sheets("blad2").PrintOut
End Sub

Dit werkt prima, maar er blijft één probleem over. Na het "ok" geven om te printen, print hij direct blad1 uit om vervolgens de printopdracht uit de macro door te voeren. M.a.w. ik krijg altijd een blad1 dubbel. Is het mogelijk om de eerste printopdracht (vóórdat hij de macro gaat aflopen) te verwijderen?

Bij voorbaat dank!

 

[VenA]

Bv

Sub printen()
  If [A4] < 1 Then Exit Sub
  If Application.Dialogs(xlDialogPrint).Show = False Then Exit Sub
  If [A4] > 1 Then Sheets("blad1").PrintOut , , [A4] - 1
  Sheets("blad2").PrintOut
End Sub

 

[HSV]

Bv.

Sub printen()
'Sheets("blad1").Activate
  If Application.Dialogs(xlDialogPrint).Show(, , , [A4].Value) Then
     Sheets("blad2").PrintOut
  End If
End Sub

Of.

Sub printen()
With Sheets("blad1")
    .Activate
    .[a2] = 1
 If Application.Dialogs(xlDialogPrint).Show Then 
      For i = 2 To .[a4]
       .[a2] = i
       .PrintOut
      Next i
    Sheets("blad2").PrintOut
    End If
End With
End Sub

 

[snb]

Je kunt toch de printpreview icoon in de snelle toegangsbalk zetten ?
Daarvoor is toch geen macro nodig ?
Die knop is dan in alle Excelbestanden beschikbaar.

 

[Bakkerbakgraag]

Probleem opgelost

Beste allemaal,
dankzij jullie hulp ben ik eruit gekomen.

Dank jullie wel!