Regel kopiëren?

[Gielleke]

Beste Helpmij leden,

Graag wil ik beroep doen op jullie kennis.
Ik ga in de loop van de tijd in dit topic mijn vraag steeds proberen uit te breiden.
Maar ik wou eerst beginnen met een begin en navragen of het wel mogenlijk is in excel?

Graag het volgende:
In het bijgevoegd voorbeeld, heb ik iets vrij simpel gemaakt 2 textboxen dat met een simpele code wordt weggeschreven naar blad1. een "datum " en "naam" in het voorbeeld. Nu is mijn vraag, is het mogenlijk da datum + de naam die word weggeschreven naar blad 1 of deze 2 gegevens ook in één keer te kopieren naar blad 2 maar enkel als het selectievakje is aan gevinkt ?

Alvast bedankt
Vriendelijke Groeten,
Angelo

 

[Cobbe]

Zo zal het wel lukken hé:

Private Sub CommandButton1_Click()
    x = Sheets("Blad1").Cells(Rows.Count, "A").End(xlUp).Row + 1
    y = Sheets("Blad2").Cells(Rows.Count, "A").End(xlUp).Row + 1
        Range("A" & x) = TextBox1
        Range("B" & x) = TextBox2
    If CheckBox1 = True Then
        Sheets("Blad2").Range("A" & y) = TextBox1
        Sheets("Blad2").Range("B" & y) = TextBox2
    End If
Unload Me
End Sub
Private Sub UserForm_Initialize()
    TextBox1 = Date
End Sub

succes, Cobbe

 

[Gielleke]

Beste Cobbe,

Eerst sorry voor de late reactie. Ben gaan werken deze middag.

Jou oplossing was meteen raak en sta er versteld van dat het eigenlijk zéér eenvoudige formule kan of zelfs bestaat!!:thumb: Dank u wel.

Heb eens gekeken voor mijn vraag verder uit te breiden en dacht zelf dat het lang zou worden maar het zal vrij kort zijn.

Ik heb het bestandje al uitgebreid en wou dat er iets bij "In" komt en bij het slectievakje aan dat het op bald 2 bij "Uit" komt te staan maar zo te zien is het mij zelf gelukt. Met natuurlijk jou code wel aals basis.

Wat ik eigenlijk als laaste normaal wil vragen. Zoals je kan zien is er een combobox bijgekomen, met de gegevens "Naar A" en "Naar B" Is er een mogenlijkheid als met vb. "Naar A" aanduid dat er op blad 2 komt te staan "Van A" ??

Is dat mogenlijk Cobbe??

Super bedankt!!
Vriendelijke Groeten,

 

[Cobbe]

Ik hoop dat ik het goed begrepen heb.

Cobbe

 

[Gielleke]

Beste Cobbe,

Bedankt voor jou reactie.
Het resulaat is er bijna. Hehe

Als ik jou code gebruik en in de combobox "Naar A" aanklikt komt er op blad 2 "Van A" wat goed is!! maar op blad 1 komt er ook "Van A" te staan maar daar zou er gewoon de regels van de combobox mogen staan dus "Naar A" begrijpt u?

Anders hoor ik het graag.:thumb:

Bedankt!!
Vriendelijke Groeten,

 

[Cobbe]

Ik hoop dat ik het goed heb aangepast:

Private Sub CommandButton1_Click()
' eerste lege regel op blad1 en blad2 bepalen
    x = Sheets("Blad1").Cells(Rows.Count, "A").End(xlUp).Row + 1
    y = Sheets("Blad2").Cells(Rows.Count, "A").End(xlUp).Row + 1
' De inhoud van het formulier naar Blad1 schrijven
    With Sheets("Blad1")
        .Range("A" & x) = TextBox1
        .Range("B" & x) = TextBox2
        .Range("C" & x) = TextBox3
        .Range("D" & x) = TextBox4
        .Range("E" & x) = ComboBox1
     End With
' Controle op checkbox - als WAAR dan ook Blad2 invullen
    If CheckBox1 = True Then
' Blad2 invullen
     With Sheets("Blad2")
        .Range("A" & y) = TextBox1
        .Range("B" & y) = TextBox2
        .Range("C" & y) = TextBox3
        .Range("D" & y) = TextBox4
' De inhoud van Combobox1 verwerken
        If ComboBox1 = "Naar A" Then antw = "Van A"
        If ComboBox1 = "Naar B" Then antw = "Van B"
' het antwoord(antw) wegschrijven naar Blad2
        .Range("E" & y) = antw
      End With
    End If
' formulier sluiten
Unload Me
End Sub
' het formulier aanpassen aan de noden
Private Sub UserForm_Initialize()
' bv de datum default op vandaag zetten
    TextBox1 = Date
' de combobox1 vullen met de keuzelijst NAAR
    ComboBox1.RowSource = "NAAR"
' en de focus zetten in de eerste textbox
    TextBox1.SetFocus
End Sub

Anders hoor ik het wel weer.

Mvgr., Cobbe

 

[Roncancio]

Wijzig:

        If ComboBox1 = "Naar A" Then antw = "Van A"
        If ComboBox1 = "Naar B" Then antw = "Van B"
        Range("E" & x) = antw

... in ...

        Range("E" & x) = ComboBox1.Value

Met vriendelijke groet,


Roncancio

 

[Gielleke]

Beste Cobbe,

Jou Code werkte perfect!!:thumb:

Heb eens even alles bekeken. En normaal is er nog één optie dat ik graag zou willen vragen of dit mogenlijk is?

Zoals je kan zien heb ik het bestand even aangepast.
Bestaat er nu nog een mogenlijkheid in om de combobox als ook nog te koppelen aan het tabblad? Als men in de combobox "Naar B" aanduid dat hij alles kopier zoals het was naar tabblad b en als hij vraagt voor "Naar C" dat hij dit zou doen naar tabblad c?

Alvast Bedankt!!
Vriendelijke Groeten,

 

[Cobbe]

Ik hoop dat je er iets uithaalt.

Cobbe

 

[Gielleke]

Beste Cobbe,

Dit is echt waar super!!:thumb:

Ik dacht dat het niet kon in excel maar toch.

Ik ga het in de loop van de week inbouwen in mijn kasboek en laat jullie dan nog wel het toaal resultaat zien.

Nogmaals dank!! Ben super blij.

Vriendelijke Groeten,

 

[Gielleke]

Beste Cobbe,

Ik wou u toch nog even graag contacteren.
Het lijkt me moeilijker dan verwacht om jou code in te bouwen in mijn bestaande code van een formulier. misschien als u wilt, zou u even een handje willen helpen aub?

Jou code:

Private Sub CommandButton1_Click()
' eerste lege regel op blad1 bepalen
    x = Sheets("A").Cells(Rows.Count, "A").End(xlUp).Row + 1
    
' De inhoud van het formulier naar Blad1 schrijven
    With Sheets("A")
        .Range("A" & x) = TextBox1
        .Range("B" & x) = TextBox2
        .Range("C" & x) = TextBox3
        .Range("D" & x) = TextBox4
        .Range("E" & x) = ComboBox1
     End With
' Controle op checkbox - als WAAR dan ook Blad2 invullen
    If CheckBox1 = True Then
Blad = Right(ComboBox1, 1)

' eerste lege regel op blad bepalen
y = Sheets(Blad).Cells(Rows.Count, "A").End(xlUp).Row + 1
' Blad2 invullen
     With Sheets(Blad)
        .Range("A" & y) = TextBox1
        .Range("B" & y) = TextBox2
        .Range("C" & y) = TextBox3
        .Range("D" & y) = TextBox4
' De inhoud van Combobox1 verwerken
        If ComboBox1 = "Naar B" Then antw = "Van A"
        If ComboBox1 = "Naar C" Then antw = "Van A"
' het antwoord(antw) wegschrijven naar Blad
        .Range("E" & y) = antw
      End With
    End If
' formulier sluiten
Unload Me
End Sub

' het formulier aanpassen aan de noden
Private Sub UserForm_Initialize()
' bv de datum default op vandaag zetten
    TextBox1 = Date
' de combobox1 vullen met de keuzelijst NAAR
    ComboBox1.RowSource = "NAAR"
' en de focus zetten in de eerste textbox
    TextBox1.SetFocus
End Sub

Mijn code van mijn formulier:

Private Sub CheckBox1_Click()
OptionButton1.Visible = False
OptionButton2.Visible = False
keuzecompactrekening

End Sub

Private Sub cmdAnnuleren_Click()
Unload Me

End Sub

Private Sub cmdInvoeren_Click()
x = Cells(Rows.Count, "A").End(xlUp).Row + 1
Range("A" & x) = txtDatum
Range("B" & x) = cboBetalingsmethode
Range("G" & x) = cboOmschrijving
If CheckBox1.Value = True Then
Range("E" & x) = txtInkomsten.Value
Range("F" & x) = txtUitgaven.Value
Else
Range("C" & x) = txtInkomsten.Value
Range("D" & x) = txtUitgaven.Value
Range("A" & x).Font.Color = txtDatum.ForeColor
Range("B" & x).Font.Color = cboBetalingsmethode.ForeColor
Range("D" & x).Font.Color = txtUitgaven.ForeColor
Range("G" & x).Font.Color = cboOmschrijving.ForeColor
End If
Unload Me

End Sub

Private Sub OptionButton1_Click()
CheckBox1.Visible = False
OptionButton2.Visible = False
keuzecompactrekening

End Sub

Private Sub OptionButton2_Click()
CheckBox1.Visible = False
OptionButton1.Visible = False
txtDatum.ForeColor = &HC0&
cboBetalingsmethode.ForeColor = &HC0&
txtUitgaven.ForeColor = &HC0&
cboOmschrijving.ForeColor = &HC0&
keuzecompactrekening

End Sub

Private Sub txtInkomsten_Change()
txtUitgaven.Visible = False
keuzecompactrekening

End Sub

Private Sub txtUitgaven_Change()
txtInkomsten.Visible = False
OptionButton1.Visible = True
OptionButton2.Visible = True
keuzecompactrekening

End Sub

Private Sub UserForm_Initialize()
txtDatum.Text = Format(Now, "dd/mm/yyyy")
cboBetalingsmethode.RowSource = "Betalingsmethode"

End Sub

Private Sub UserForm_Activate()
OptionButton1.Visible = False
OptionButton2.Visible = False

End Sub

De waarden van de combobox en de andere kleine details zal me beste wel lukken. Als u even wil kijken voor het grotere werk?

Alvast Bedankt!!
Vriendelijke Groeten,:thumb:

 

[Cobbe]

Het lijkt me moeilijk om die code aan te passen of te herschrijven als ik het bestand niet heb.
Kan je dit bestand (zonder gevoelige gegevens) niet posten?

Als het te groot is kan het ook via cobbe at skynet punt be

Cobbe