Rekenen met letters

[Peter B]

Ik moet in een sheet rekenen met 3 letters die in willekeurige combinaties voorkomen Ik stel de letters gelijk aan getallen d.m.v. een vertaaltabel middels VLOOKUP.

Stel bv. A=50; B=10; C=30.

Dan worden de antwoorden:
A x B x C = 50 x 10 x 30 = 15.000
C x C x C = 30 x 30 x 30 = 9.000

En de formule:
=VLOOKUP(cel1;Vertaaltabel;2;FALSE) * VLOOKUP(cel2;Vertaaltabel;2;FALSE) * VLOOKUP(cel3;Vertaaltabel;2;FALSE)

Is er een slimmere manier om dit te doen (alleen formules)?

 

[VenA]

Bedoel je zoiets?

=KIEZEN(CODE(A1)-64;50;10;30)*KIEZEN(CODE(B1)-64;50;10;30)*KIEZEN(CODE(C1)-64;50;10;30)

 

[sylvester-ponte]

Hallo Peter, heb je ook een voorbeeld excel bestandje?
en kijk ook een bij namen definiëren.

 

[Gijsbert1]

C*C*C = 27.000

 

[AlexCEL]

Nog een optie:

=50^AANTAL.ALS(A1:C1;"A")*10^AANTAL.ALS(A1:C1;"B")*30^AANTAL.ALS(A1:C1;"C")

Verder nog:

=KIEZEN(VERGELIJKEN(A1;{"A";"B";"C"};0);50;10;30)*KIEZEN(VERGELIJKEN(B1;{"A";"B";"C"};0);50;10;30)*KIEZEN(VERGELIJKEN(C1;{"A";"B";"C"};0);50;10;30)

Aangenomen dat jouw rij met letters in bereik A1:C1 staat...

 

[Peekhamer]

Ik zou het met Naamformules oplossen.

 

[Peekhamer]

edit: dubbelpost

 

[Peter B]

En ook ik leer hierbij weer dat een representatief voorbeeld nodig is ... Hoe simpel het ook allemaal lijkt.

Zie hierbij dan ook een representatief voorbeeldbestand:
- Geen A, B, C maar H, L, M. Waardoor de formule van VenA helaas niet werkt
- Geen aaneengesloten kolommen/ ranges waardoor de eerste formule van AlexCEL niet werkt en COUNTIF({...};"L") werkt dus ook niet

Bekijk bijlage Voorbeeld Helpmij - Reken met letters.xlsx

 

[AlexCEL]

@Peekhamer: je kunt een bericht ook gewoon verwijderen...

 

[AlexCEL]

Mijn eerste formule kan nog steeds dacht ik zo...

=1^AANTAL.ALS(B2:I2;"L")*3^AANTAL.ALS(B2:I2;"M")*15^AANTAL.ALS(B2:I2;"H")

 

[Peter B]

Je hebt gelijk mits in de overige "niet relevante" kolommen er geen H, M, L voorkomt

@Gijsbert1: Je hebt gelijk. Daarom kan ik beter Excel gebruiken ...

 

[rebmog]

Andere optie: geef cel O2 de naam L, O3 de naam M en O4 de naam H en gebruik vervolgens de formule:

=INDIRECT(B2)*INDIRECT(D2)*INDIRECT(G2)*INDIRECT(H2)*INDIRECT(I2)

 

[Gijsbert1]

De formule van AlexCel vind ik persoonlijk het chicst.
Ik zou de "niet relevante kolommen" elders neer zetten zodat je aaneengesloten bereiken creëert.
Hier is al eerder een Topic over geweest: : http://www.helpmij.nl/forum/showthread.php/363790-aantal-als-en-niet-aaneengesloten-bereik

 

[MarcelBeug]

Deze vind ik ook wel mooi, alleen moet de tabel dan wel gesorteerd zijn op letter. En het mag telkens maar 1 letter zijn.

=PRODUCT(ZOEKEN(DEEL(B2&D2&G2&H2&I2;{1;2;3;4;5};1);$N$2:$N$4;$O$2:$O$4))

 

[Peter B]

Ik meende dat het handig was om de L, M, H direct naast de kolom(men) te zetten waar het over gaat voor een snelle controle. Ik ben dat nu idd. aan het corrigeren zodat ik aaneengesloten bereiken heb.

Ik vind de INDIRECT van rebmog ook wel heel slim. Toch ga ik voor de variant van AlexCEL.

Bedankt allemaal voor het meedenken!

... en toen zag ik dat ook Marcel had gereageerd met een schoonheid. Hoe verzin je het? Ik blijf echter bij mijn standpunt dat ik de variant van AlexCEL ga gebruiken ...

 

[AlexCEL]

In antwoord op post #11: AANTAL.ALS en niet-aaneengesloten bereiken blijft lastig...

PS als de waarde van "L" altijd 1 is, kan de formule nog korter.

=3^AANTAL.ALS(B2:I2;"M")*15^AANTAL.ALS(B2:I2;"H")

Dit was een leuke vraag. :thumb:

 

[MarcelBeug]

Als ik die van AlexCEL en die van mij combineer, dan kom ik op de volgende matrixformule (bevestigen met Ctrl+Shift+Enter, niet gewoon Enter):

=PRODUCT($O$2:$O$4^AANTAL.ALS(B2:I2;$N$2:$N$4))

De voorwaarden die ik in post #14 noemde, zijn hier niet van toepassing.

 

[Ginger]

Tja, misschien is het nóg slimmer om tekens te gebruiken waar ze voor dienen. Dus met cijfers kan je rekenen en met letters kan je schrijven.
Ik kan me niet voorstellen dat een faktuur oid er duidelijker op wordt als daar letters voor in de plaats staan.