Rijen invoegen middels loop

[Albatros]

Hoi,

In bijgaand Excel bestand, wil ik om de lay-out te verfraaien, rijen invoegen, rijhoogtes aanpassen, en de tussenrijen weer verwijderen bij onderhoud aan het bestand.
Nu heb ik alle rijen apart benoemd, maar ik vraag mij af of dit niet middels een eenvoudigere oplossing kan (loop)?.
Wie heeft er een idee?

Albatros

 

[namliam]

dim i as integer
for i = 8 to 80
     range(I&":"& I).Insert
next i

Zoiets?

 

[Albatros]

Beste Namliam,

Bedankt voor de reactie, maar ik krijg deze code niet geïntegreerd .

Albatros

 

[namliam]

De gegeven code zou een 1:1 vervangen moeten zijn voor:

    Range( _
        "6:6,7:7,8:8,9:9,10:10,11:11,12:12,13:13,14:14,15:15,16:16,17:17,18:18,19:19,20:20,21:21,22:22,23:23,24:24,25:25,26:26,27:27,28:28,29:29,30:30,31:31,32:32,33:33,34:34,35:35,36:36,37:37,38:38,39:39" _
        ).Select
    Selection.Insert

Afhanelijk natuurlijk van de 8 en 80 wat je daar invult om te bepalen hoeveel rijen je insert.

 

[HSV]

Test het maar eens.

Sub rij_inv_hgte()
Dim i As Long
Application.ScreenUpdating = False
For i = 32 To 6 Step -1
With Rows(i)
     .RowHeight = 25
     .Insert
     .Offset(1).RowHeight = 8.25
   End With
 Next i
  Rows(6).RowHeight = 8.25
End Sub

 

[Albatros]

Beste Helpers,

Dit gaat erop lijken!
Echter hoe krijg ik de smalle rijen kleurloos?
Met onderstaande lukt het niet. Mogelijk een verkeerde plaats?

Sub rij_inv_hgte_HM()
Dim i As Long
Application.ScreenUpdating = False
For i = 32 To 6 Step -1
With Rows(i)
     .RowHeight = 25
     .Insert
     .Offset(1).RowHeight = 8.25
       With Selection.Interior
        .Pattern = xlNone
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
   End With
 Next i
  Rows(6).RowHeight = 8.25

Albatros

 

[HSV]

Niet zozeer, maar omdat er geen selection is.
En als het alleen maar om de kleur gaat.

Sub rij_inv_hgte()
Dim i As Long
Application.ScreenUpdating = False
For i = 32 To 6 Step -1
With Rows(i)
     .RowHeight = 25
     .Insert
     With .Offset(1)
          .RowHeight = 8.25
          .Interior.ColorIndex = xlNone
     End With
   End With
 Next i
  With Rows(6)
     .RowHeight = 8.25
     .Interior.ColorIndex = xlNone
    End With
End Sub

 

[Albatros]

Yes!

Dat is wat ik wilde hebben! :thumb: :thumb:

namliam, en vooral HSV, bedankt voor de moeite.

Albatros