rijen verwijderen op basis van de "A" en "H"

[Depant]

Hallo allemaal,

Zou iemand mij kunnen helpen.
Onderstaande code werkt prima. Maar ik zou ook graag in dezelfde kolom de rijen met " H" willen verwijderen.
Hoe moet ik dat doen?


Bekijk bijlage ys.xlsm

Groeten Henk.



Sub Methode1()

Dim i As Long

With ActiveWorkbook.Sheets(1)

For i = 100000 To 1 Step -1

If .Cells(i, "C") = "H" Then

.Cells(i, "C").EntireRow.Delete

End If

Next i

End With

End Sub

 

[OctaFish]

Of het de handigste oplossing is weet ik niet (waarom niet eerst de laatste gevulde rij eerst opzoeken?) maar de aanpassing is vrij simpel.

        If .Cells(i, "C") = "H" Or .Cells(i, "C") = "A" Then

 

[Depant]

Hoi,

Ik doe eigenlijk niet veel met excel, en dit is voor mij onzettend fijne hulp.
Hartelijk bedankt!!

:thumb:

 

[OctaFish]

Hier een uitbreiding die de laatste rij opzoekt.

Sub Methode1()
Dim i As Long, LastRow As Long
Dim sht As Worksheet
    
    ActiveSheet.UsedRange
    Set sht = ActiveSheet
    LastRow = sht.Cells(sht.Rows.Count, "A").End(xlUp).Row
    With sht
        For i = LastRow To 1 Step -1
            If .Cells(i, "C") = "H" Or .Cells(i, "C") = "A" Then
                .Cells(i, "C").EntireRow.Delete
            End If
        Next i
    End With
 
End Sub

 

[edmoor]

Zonder loop:

Sub Methode1()
    Dim LR As Long
    With ActiveWorkbook.Sheets("ys")
        LR = .Cells(.Rows.Count, "A").End(xlUp).Row
        .Rows("1:1").AutoFilter
        .Range("A1:L" & LR).AutoFilter Field:=3, Criteria1:="=A", Operator:=xlOr, Criteria2:="=H"
        LR = .Cells(.Rows.Count, "A").End(xlUp).Row
        Application.DisplayAlerts = False
        .Range("A2:M" & LR).Delete
        Application.DisplayAlerts = True
        .Rows("1:1").AutoFilter
    End With
End Sub

 

[Depant]

Hartelijk dank

Goedemorgen,


Hartelijk dank het werkt supersnel.

:thumb::thumb::thumb:

 

[VenA]

Mij lijkt dit wel voldoende

Sub VenA()
  With Sheets("ys").Cells(1).CurrentRegion
    .AutoFilter 3, Array("A", "H"), xlFilterValues 'of .AutoFilter 3, "<>"
    .Offset(1).EntireRow.Delete
    .AutoFilter
  End With
End Sub