SHA-256 sleutel in excel

[sanders1969]

Kan iemand mij helpen wat ik kennelijk fout doe?
In de onderstaande link kan je de code om een SHA-256 sleutel in excel te genereren.


Het loopt vast bij: Dim clsX As CSHA256
Kennelijk moet ik nog wat doen maar weet niet wat.

strSHA256Key = SHA256("ik ben benieuwd")

Public Function SHA256(sMessage As String)

    Dim clsX As CSHA256
    Set clsX = New CSHA256

    SHA256 = clsX.SHA256(sMessage)

    Set clsX = Nothing

End Function

 

[sanders1969]

Vervolg
Regel: strSHA256Key = SHA256("ik ben benieuwd") staat uiteraard in een aparte sub maar voor de eenvoud heb ik het even er boven geplaatst.

 

[edmoor]

Je zal de Class Module missen.

 

[sanders1969]

Waar kan ik die ergens vandaan halen of moet ik die ergens registeren of refereren?

 

[sanders1969]

Ik heb zelf in MS Access MD5Hash en deze werk puur op syntaxis, ook SHA1 werkt puur op syntaxis.

 

[alphamax]

Hier staat de code van je class-module
https://stackoverflow.com/questions/22672564/porting-sha-256-library-to-excel in de link die je zelf gaf.
Zie bijlage voor alles in 1 bestand, je start in "Main".

 

[alphamax]

Maar het kan natuurlijk ook zonder extra klasse of module, want deze encryptie zit al standaard in windows.

Option Explicit

Public Sub Main()
    Dim strSHA256Key As String

    strSHA256Key = SHA256("ik ben benieuwd")

End Sub

Public Function SHA256(strMessage As String) As String
    Dim abytHash() As Byte
    Dim iabytHash As Long
    Dim objEncoded As Object
    Dim objProvider As Object

        SHA256 = vbNullString
    
        Set objEncoded = CreateObject("System.Text.UTF8Encoding")
        Set objProvider = CreateObject("System.Security.Cryptography.SHA256Managed")
    
        abytHash = objProvider.ComputeHash_2(objEncoded.GetBytes_4(strMessage))
    
        For iabytHash = LBound(abytHash) To UBound(abytHash)
            SHA256 = SHA256 & Hex(abytHash(iabytHash) \ 16) & Hex(abytHash(iabytHash) Mod 16)
        Next

End Function

bron: https://stackoverflow.com/questions/125785/password-hash-function-for-excel-vba/125844#125844

 

[sanders1969]

Gelukt!
Mijn dank is weer erg groot!
Ook handig dat je de class-module kan slepen.
Ik had het eerst opgeslagen en probeerde het te importeren maar zag niet 1-2-3 of dat ging lukken.
Vervolgens class-module geklikt en gesleept naar de juiste project.

 

[sanders1969]

Haha, die is nog beter!
Thanks!