snelkoppeling in word

[Sandra1992]

Hallo allemaal,

Ik heb een inschrijfformulier gemaakt in word. Deze dienen mensen in te vullen en door te mailen.
Is het mogelijk om een soort button te maken in word waar mensen op klikken waardoor het word document automatisch als bijlage wordt verstuurd per mail?

Hoor graag jullie ideeën!

Groetjes Sandra

 

[OctaFish]

Ik gebruik zelf een functie om te mailen. Die ziet er zo uit:

Function Mailen()
Dim TempFilePath As String, TempFileName As String, FileExtStr As String
    
    '--------------------------------------------------------------------------------------------------
    ' Tijdelijk bestand opslaan...
    '--------------------------------------------------------------------------------------------------
    TempFilePath = Environ$("temp") & "\" 'Save the new workbook/Mail it/Delete it
    TempFileName = "Intakeformulier Word voor Beginners - " & sNaam  'Nieuwe mapnaam
    TempFileName = Replace(TempFileName, "/", "-")
    FileExtStr = ".doc"
    '--------------------------------------------------------------------------------------------------
    ' Mail maken voor Outlook...
    '--------------------------------------------------------------------------------------------------
    Set OutApp = CreateObject("Outlook.Application")
    OutApp.Session.Logon
    Set OutMail = OutApp.CreateItem(0)

    Set aDoc = ActiveDocument
    With aDoc
        Application.DisplayAlerts = False
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=wdFormatDocument
        'knop Verzenden verbergen
        For Each f In ThisDocument.Fields
            If Not f.OLEFormat Is Nothing Then
                Select Case f.OLEFormat.ClassType
                    Case "Forms.CommandButton.1"
                        Set obj = f.OLEFormat.Object
                        obj.Visible = False
                        Exit For
                End Select
            End If
        Next f
        .Save NoPrompt:=True, OriginalFormat:=wdOriginalDocumentFormat
        Application.DisplayAlerts = True
        On Error Resume Next
        With OutMail
            'De standaard mailadressen........
            '--------------------------------------------------------------------------------------------------
            .To = "mailme@dommejongen.nl"
            .Subject = "Intakeformulier Word voor Beginners - " & sNaam
            .Body = "Inschrijving voor cursus Word voor Beginners " & vbCrLf & vbCrLf & "Datum: " & sDatum
            '------------------------------------------------------------------------------------------------
            ' Als er geen bijlage wordt verstuurd, dan de volgende regel verwijderen...
            '------------------------------------------------------------------------------------------------
            .Attachments.Add aDoc.FullName
            ''.Display 'of .Send gebruiken, als je gelijk wilt verzenden.
            .Send
            flag = True
        End With
        On Error GoTo 0
        .Close SaveChanges:=False
    End With

    '------------------------------------------------------------------------------------------------
    ' Bestanden opruimen, en variabele leegmaken...
    '------------------------------------------------------------------------------------------------
    On Error Resume Next
    Kill TempFilePath & TempFileName & FileExtStr
    Set OutMail = Nothing
    Set OutApp = Nothing
    
    If flag = True Then
        MsgBox "De aanvraag is verstuurd naar de planner." & vbLf _
            & "U kunt in de TOPdesk SelfServiceDesk planner zien wanneer de cursus wordt gegeven.", vbInformation
    Else
        MsgBox "Het versturen van de aanvraag is mislukt." & vbLf _
            & "Controleer of uw gegevens correct zijn, " & vbLf _
            & "en verbeter deze indien nodig. " & vbLf _
            & "Probeer daarna om de aanvraag nogmaals te versturen." & vbLf & vbLf _
            & "Lukt het dan nog niet, neem dan contact op met de planningscoördinator.", vbInformation
    End If

End Function

Daar zitten wat trucjes in om knoppen te verbergen in het brondocument, die je er uiteraard uit kunt halen.