SOM.ALS en AANTAL.ALS

[jbontjejr]

Hallo, nog maar eens een vraagje.
Hoe ziet de SOM.ALS en AANTAL.ALS functie eruit waarin 2 of meerdere criteria getoetst worden voordat ze worden meegenomen?

 

[Roncancio]

Hallo, nog maar eens een vraagje.
Hoe ziet de SOM.ALS en AANTAL.ALS functie eruit waarin 2 of meerdere criteria getoetst worden voordat ze worden meegenomen?

Heb je een voorbeeld?

Met vriendelijke groet,


Roncancio

 

[bandito bob]

Beide kan je doen met SOMPRODUCT(), maar b.v. ook met een DBSOM en DBAANTAL.

 

[jbontjejr]

Heb je een voorbeeld?

Met vriendelijke groet,


Roncancio

Ik hoop dat je eruit komt. de formules die ik als tekst erbij heb gezet geven alleen de richting aan waarin ik denk.

PS. bestaat er ook een mogelijkheid waardoor je op basis van 2 criteria een hele rij kan kopieren naar een ander tabblad?

 

[bandito bob]

Voor cel B27:

=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27))

kopieeren naar beneden.

Voor cel D27:

=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*D2:E21)

oeps, er staan er nog 2...
Voor F27:

=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$3))+SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$4))+SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$5))

voor H27:

=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$3)*D$2:E$21)+SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$4)*D$2:E$21)+SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$5)*D$2:E$21)

De 2 laatste formules kunnen denk ik wel wat korter met een OF, maar daar kwam ik zo snel niet uit.

 

[jbontjejr]

Voor cel B27:

=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27))

kopieeren naar beneden.

Voor cel D27:

=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*D2:E21)

oeps, er staan er nog 2...
Voor F27:

=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$3))+SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$4))+SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$5))

voor H27:

=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$3)*D$2:E$21)+SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$4)*D$2:E$21)+SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*(F$2:F$21=H$5)*D$2:E$21)

De 2 laatste formules kunnen denk ik wel wat korter met een OF, maar daar kwam ik zo snel niet uit.

Bedankt voor je reactie!
Maar die laatste 2 formules zijn idd te lang. ze moeten namelijk aan 7 waardes worden getoetst. Heb ook al even wat geprobeerd met OF maar kom er ook niet uit. wie helpt mij met het laatste stukje?

 

[Thoralf]

Ik heb even de laatste formule genomen en aangepast wordt dat dan:
=SOMPRODUCT((B$2:B$21="Hoofd FG")*(C$2:C$21=A27)*((F$2:F$21=H$3)+(F$2:F$21=H$4)+(F$2:F$21=H$5))*D$2:E$21)

In dit soort matrix-achtige formules wordt een EN-relatie weergegeven met een * (maal-teken) en een OF-relatie door een + (plus-teken)

groeten
Thoralf

 

[jbontjejr]

Mensen allemaal hartelijk dank! :thumb: