som van tijden naar boven afronden per 5 minuten

[twuser]

besten,

ik heb een excel file die per dag de vluchttijden bijhoud en deze moet afronden op de bovenliggende 5minuten.

voorbeeld :
op vandaag zijn er 2 vluchten, de eerste is van 6u56 tot 7u12 en de 2de is van 14u42 tot 14u57 (in excel op een rij per datum ingevuld) nu tel ik in diezelfde rij ook de totale vluchttijd per dag op afgerond naar de bovenliggende 5 minuten. voor dit voorbeeld dus 7u12-6u56 = 16minuten afgerond naar volgende 5min geeft dit 20min (ok), voor de andere is dit 14u57-14u57 = 15min maar excel geeft dit resultaat weer als 20min wat dus niet correct is. de formule die ik hiervoor gebruik is de volgende : =AFRONDEN.BOVEN((F54-D54);"00:05")+AFRONDEN.BOVEN((J54-H54);"00:05")
met F54 = 6:56, D54= 7:12 en J54=14:42 en H54=14:57

het resultaat van deze formule is dus 40 min terwijl dit 35 moet zijn.
is er iemand die hier een oplossing voor heeft?

alvast dank voor de hulp.
wim

 

[Conseclusie]

Je rondt nu beide tussenuitkomsten af naar boven, terwijl je over het totaal één keer moet afronden.
Dus:

=AFRONDEN.BOVEN((F4-D4+J4-H4);"00:05")

 

[wampier]

Het echte probleem is dat excel voor tijden met fracties werkt in niet werkelijke minuten. Volgende probleem is dat excel vervolgens de fracties in deelberekeningen afrond.

als je 1ms van de tijd afhaalt gaat het wel goed . (ja letterlijk 1 ms).

=AFRONDEN.BOVEN((F4-D4-0,00000001);"00:05")+AFRONDEN.BOVEN((J4-H4-0,00000001);"00:05")

 

[twuser]

er moet wel degelijk per vlucht naar de bovenliggende 5 min worden afgerond en niet over het total, is hier dan ook een oplossing voor of moet ik telkens in een andere (hulp)cel een berekening als tussenstap laten uitvoeren?

 

[MarcelBeug]

Misschien is het toch maar het veiligste om "ouderwets" om te rekenen naar hele waarden per minuut (dus 1 minuut = 1), daarmee afronden en sommeren, en dan weer terugrekenen naar tijdfractie.

=SOM(AFRONDEN.BOVEN((60*(UUR(F4)-UUR(D4))+MINUUT(F4)-MINUUT(D4));5);AFRONDEN.BOVEN((60*(UUR(J4)-UUR(H4))+MINUUT(J4)-MINUUT(H4));5))/24/60

 

[twuser]

ik probeer het uit en laat je iets weten, alvast bedankt.

 

[wampier]

Wat werkte er niet aan mijn formule?

 

[snb]

Vermijd samengevoegde cellen !

=CEILING(MOD(--TEXT(F4-D4;"umm");100);5)+CEILING(MOD(--TEXT(J4-H4;"umm");100);5)

of

=TIME(HOUR((F4-D4)+(J4-H4));CEILING(MINUTE(F4-D4);5)+CEILING(MINUTE(J4-H4);5);0)

 

[twuser]

cellen zijn niet samengevoegd, maar het gaat wel om soms om een 8 tal vluchten per dag, dus de formule wordt wel heel erg lang.

@wampier, uw formule werkt wel, maar weet niet of dit voor elke tijd gaat werken.

 

[snb]

In het bestand dat je plaatste zijn alle cellen die gegevens bevatten samengevoegd.
Je hebt zelf bedacht dat per vlucht afgerond moet worden op 5 minuten.
Dan ontkom je niet aan 8 elementen in een formule.
Ik heb wel langere formules voorbij zien komen.

8 vluchten:

=CEILING(TEXT(F4-D4;"[m]");5)+CEILING(TEXT(J4-H4;"[m]");5)+CEILING(TEXT(F5-D5;"[m]");5)+CEILING(TEXT(J5-H5;"[m]");5)+CEILING(TEXT(F6-D6;"[m]");5)+CEILING(TEXT(J6-H6;"[m]");5)+CEILING(TEXT(F7-D7;"[m]");5)+CEILING(TEXT(J7-H7;"[m]");5)

Maar ook hier geldt: structuring precedes coding:

als de aankomsttijden in M15:M22 staan en de vertrektijden in L15:L22 gaat het met de matrixformule:

=SUM(CEILING(TEXT(M15:M22-L15:L22;"[m]");5))

 

[MarcelBeug]

Voor een uitbreidbare formule beveel ik deze variant van Wampier's formule aan:

=SOMPRODUCT(AFRONDEN.BOVEN((F4:J4-D4:H4-0,00000001);"00:05");{1\0\0\0\1})

F4:J4 is het bereik vanaf de eerste eindtijd tot en met de laatste eindtijd.
D4:H4 is het bereik vanaf de eerste begintijd tot en met de laatste begintijd.
De {1\0\0\0\1} is het patroon van de kolommen die je wel en niet moeten hebben, dus qua eindtijden: F wel, G niet, H niet, I niet, J wel.
Voorwaarde voor juiste werking is dat zich geen tekstuele gegevens in het bereik bevinden.

 

[twuser]

na enige tijd alles uit te testen blijkt de formule van wampier perfect te werken.

aan allen hartelijk bedankt voor de geboden hulp.

wim