SOMMEN.ALS - Meerdere criteria uit één kolom selecteren

[bigstefanus]

Beste Helpers,

Ik ben reeds een tijdje aan het vogelen met de SOMMEN.ALS formule. Ik kom er grotendeels uit, maar het enige wat niet lukt is om meerdere criteria uit één kolom te filteren, om vervolgens een bedrag te berekenen.

Misschien dat een voorbeeld verhelderend werkt:

Kolom X Kolom Y Kolom Z
A A 15
B A 20
C B 20
D B 10
A A 25
A A 30
B A 20

Uit kolom X, wil ik de getallen B én C, uit kolom Y alleen A, en kolom Z is het optelbereik, mits aan de voorwaarden van kolom X en Y is voldaan.

Het lukt mij alleen om de formule te berekenen als ik uit kolom X maar één criterium nodig heb (bijv. B). Weet iemand hoe het mogelijk is om meerdere criteria mee te nemen uit deze kolom (B&C)?

Alvast bedankt voor de moeite!

 

[Peter B]

Dat kan op deze manier. Wellicht weet iemand een fraaiere oplossing ...

=SOMMEN.ALS(Z1:Z7;X1:X7;"B";Y1:Y7;"A")+SOMMEN.ALS(Z1:Z7;X1:X7;"C";Y1:Y7;"A")

 

[HSV]

Als je dit fraaier vindt ?

=SOMPRODUCT((X1:X7={"B";"C"})*(Y1:Y7="A")*(Z1:Z7))

 

[WHER]

Of deze:

=SOMMEN.ALS(Z1:Z7;X1:X7;{"B";"C"};Y1:Y7;"A")

 

[HSV]

Ik had het al getest Wher.

Die kan niet omgaan met de matrix.
Verander de B rechts van de C in een A, dan zie je het dat het resultaat hetzelfde blijft.

 

[WHER]

Dju toch, je hebt gelijk.
Wel moet ik in jouw formule de {"B";"C"} vervangen door {"B"\"C"} om hem bij mij te laten functioneren, maar dat probleem zijn we nog tegenkomen dacht ik.

 

[HSV]

Klopt het scheidingsteken is versie afhankelijk, maar soms krijg ik bestandjes binnen die het wel weer doen met de backslash.
Je krijgt er soms geen hoogte van.

 

[sylvester-ponte]

dit dus

=SOMMEN.ALS(Z1:Z7;X1:X7;{"B"\"C"};Y1:Y7;"A")

 

[HSV]

Ja, maar die werkt helaas niet Sylvester.

Zie #4 en #5.

 

[sylvester-ponte]

oh, bij mij wel :shocked:

ps hier gebruik ik 2010

 

[sylvester-ponte]

en met ";" ipv "\" werkt hij ook

 

[HSV]

In Excel 2007 niet.

Werkt dit bij jou?

 

[sylvester-ponte]

Harry, je hebt helemaal gelijk :thumb:
hij ziet in {"B";"C"} alleen de "B"
dus wordt het uiteindelijk toch:

=SOMPRODUCT((X1:X7={"B"\"C"})*(Y1:Y7="A")*(Z1:Z7))

 

[HSV]

Ik dacht al, dát ook nog jaartal afhankelijk?

Een voorbeeldje maakt het toch weer duidelijker.
Bedankt voor je test. :thumb:

 

[WHER]

Nog eentje toegevoegd, weliswaar een beetje "anders doen om anders te doen"

 

[snb]

of:

Sub M_snb()
    x2 = [sum((X1:X7&Y1:Y7={"BA","CA"})*Z1:Z7)]
End Sub

of

=SUMPRODUCT((X1:X7&Y1:Y7={"BA"\"CA"})*Z1:Z7)

 

[bigstefanus]

Helpers,

Bedankt voor de snelle reacties, het werkt nu!

Nog één aanvullende vraag: is het ook mogelijk om waardes uit te sluiten? Er is namelijk één kolom die tien verschillende categorieën bevat, waarvan er negen mee moeten worden genomen in de berekening, en één uitgesloten moet worden.

Alvast bedankt!

 

[sylvester-ponte]

1 waarde? gewoon weg halen :d

 

[Peter B]

Uitsluiten van 1 waarde in SOMMEN.ALS (hier mag dus alles in kolom X m.u.v. "A"):

=SOMMEN.ALS(Z1:Z7;X1:X7;"<>A")

 

[bigstefanus]

Bedankt allen! Ben er uit