Sorteren op rij in excel

[annetiti]

Hallo

Ik zit met een probleem ivm sorteren op rij niveau
In een gegevensbestand in excel zou ik een reeks cellen (punten ) willen sorteren van klein naar groot en dit voor meerdere rijen.
In bijlage een voorbeeld. Zou dit graag via een macro doen daar deze toepassing op verschillend werkbladen moet gebeuren.
Kan er iemand mij helpen het lukt me niet!
Hartelijk dank
Anne
bijlage: Bekijk bijlage sort vraag.zip

 

[Niels28]

Sub Sorteren()
Dim irow As Integer
Dim x As Integer
irow = Cells(Rows.Count, 1).End(xlUp).Row
For x = 2 To irow

    Activesheet.Sort.SortFields.Clear
    Activesheet.Sort.SortFields.Add Key:=Range("E" & x & ":J" & x), _
        SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With Activesheet.Sort
        .SetRange Range("E" & x & ":J" & x)
        .Header = xlGuess
        .MatchCase = False
        .Orientation = xlLeftToRight
        .SortMethod = xlPinYin
        .Apply
    End With
    Next
End Sub

 

[Cobbe]

Deze kan je gebruiken als je ooit eens per rij-selectie wil sorteren op rij:

Sub RijSortering()
With Selection
    .Sort Key1:=Range(.Address), Order1:=xlAscending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlLeftToRight
End With
End Sub

 

[Niels28]

Dan de verkorte versie met dank aan Cobbe

Sub Sorteren1()
Application.ScreenUpdating = False
Dim irow As Integer
Dim x As Integer
irow = Cells(Rows.Count, 1).End(xlUp).Row
For x = 2 To irow
With Range("E" & x & ":J" & x)
    .Sort Key1:=Range(.Address), Order1:=xlAscending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlLeftToRight
End With
    Next
End Sub

Niels

 

[annetiti]

Rijen sorteren

Dag Niels en Cobbe

Hartelijk dank voor deze snelle reacties.
Hier heb ik wat bijgeleerd.
En ja het werkt prima, verschillende keren uitgetest in rekenbladen.


groeten Anneititi

Waar kan ik dit bericht als opgelost zetten?

 

[Niels28]

Graag gedaan,

de vraag zet je op opgelost net boven je eerste vraag door "status op opgelost zetten" aan te klikken.

Niels

 

[annetiti]

Dank je wel
annetiti