Splitsen tekst in een zin

[Omteleren]

Graag het eerste getal na de ":" kolom C
Graag het eerste getal na de "-" kolom D


Kenmerk:13400579-99155246, einde van het jaar
Wil graag de getallen in een aparte kolom 13400579 en 99155246

Zie bijgevoegde voorbeeld en groen is gewenst. Wie kan er helpen met het maken van de formule.
(versie Excel 2016)

 

[SjonR]

Zijn de gewenste getallen altijd 8 cijfers lang en staat er standaard "Kenmerk:" voor?

Als het altijd zo is als in het voorbeeld;

=DEEL(A4;9;8)

en

=DEEL(A4;18;8)

 

[Omteleren]

Er staat altijd kenmerk voor, maar cijfers kunnen korter of langer zijn.
1e getal is 7 0f 8 characters (helaas) anders via formule deel kunnen doen!

 

[SjonR]

maar de : en de - staan er altijd in?

 

[Omteleren]

Ja, altijd: en -

 

[Omteleren]

Wellicht de lengte als voorwaarde nemen, door de lengte te tellen. Ik vind deze formules altijd lasting. Hier op het forum zijn er een aantal knappe tovenaars bij.

 

[Omteleren]

Kenmerk:3394841-99155241, Einde van het jaar

gaat niet goed bij 7 cijferige getallen. Getallen zijn 7 of 8.


3394841- 9155241,

 

[Senso]

Kun je dat niet bereiken met Tekst naar kolommen?

 

[Omteleren]

Splitst met "> kenmerk vervalt en begint vanaf 1e getal.
Tekst na kolommen werkt als je het een aantal keren doet. De tabel wordt telkens aangevuld met nieuwe regels en dan is het wel onhandig om tekst na kolommen te doen.
Zou heel mooi zijn als dat zou kunnen.

 

[JeanPaul28]

Kan dit dienen

 

[HSV]

=1*DEEL(A4;VERGELIJKEN(1;--ISGETAL(--DEEL(A4;RIJ($1:$15);1));0);VIND.SPEC("-";A4)-VERGELIJKEN(1;--ISGETAL(1*DEEL(A4;RIJ($1:$15);1));0))

en

=ZOEKEN(10^99;INDEX(--DEEL($A4;VIND.ALLES("-";$A4)+1;RIJ(1:15));0))

 

[AHulpje]

Nog eentje, keus genoeg dus:

=DEEL(A4;9;VIND.SPEC("-";A4)-9)
=DEEL(A4;VIND.SPEC("-";A4)+1;VIND.SPEC(",";A4)-VIND.SPEC("-";A4)-1)

 

[Omteleren]

HSV ik ga het testen!

 

[Omteleren]

Van Hulpje werkt het helemaal perfect en van HSV werkt 50%, de eerste forumule niet.
ik ben er echt heel blij mee. Slaap er vanavond beter van.
Bedankt voor jullie hulp. Knap gedaan!

 

[HSV]

Die formule moet je waarschijnlijk nog afsluiten met Ctrl+Shift+Enter.
Maar de formules worden een beetje roestig zo te zien.

 

[emields]

nu we toch bezig zijn en er geen voetbal is.

 

[peter59]

Dan nog maar een duit in het zakje.
D.m.v. Power Query.

 

[snb]

2 klassiekers:

=TRIM(MID(SUBSTITUTE(A4;"-";REPT(" ";20));9;20))

=TRIM(MID(SUBSTITUTE(SUBSTITUTE(A4;"-";REPT(" ";20));",";REPT(" ";20));29;20))

 

[AlexCEL]

Mocht je een keer upgraden naar Excel 365:

=TEKST.NA(TEKST.VOOR(A4;"-");":")
=TEKST.NA(TEKST.VOOR(A4;",");"-")

Voor respectievelijk eerste en tweede getal.