substitueren in combinatie met vert.zoeken

[Friend]

Beste forummers,

Graag zou ik substitueren willen combineren met vert.zoeken

Zelf kom ik hier niet uit.

Is dit mogelijk?

In de bijlage een proefbestandje.

ik zou graag in kolom D de waarde willen vervangen
1 wordt ja
2 wordt nee

En als de persoon niet gevonden wordt geen waarde.

Friend

 

[JEC.]

bvb

=CHOOSE(IF($C3="";"";VLOOKUP($C3;data!$C$1:$D$5;2;0));"ja";"nee")

 

[AlexCEL]

Excel 365 optie:

=ALS.FOUT(SCHAKELEN(VERT.ZOEKEN(F2;$C$2:$D$5;2;0);1;"ja";2;"nee");"")

 

[Friend]

JV en Alex,

Hartelijk dank voor jullie reactie :thumb:

Dat werkt beiden mooi.

JV bij jouw code begrijp ik alleen niet goed wat maakt dat code 1 ja wordt en code 2 nee.

Mocht je het nog willen uitleggen graag.

Maar sowieso allebei hartelijk dank.

Friend

 

[JEC.]

Werkt hetzelfde als die van Alex maar de parametervolgorde van SCHAKELEN is net iets anders dan die van KIEZEN

Verticaal zoeken komt met de uitkomst 1 of 2.
-De eerste parameter van KIEZEN wordt gevraagd om een index-getal (1 of 2 dus vanuit vert.zoeken).
-De volgende parameters zijn de uitkomsten. Dus waarde1 wordt gekozen als de uitkomst van de eerste parameter 1 is. Waarde2 wordt gekozen als de uitkomst 2 is...etc

=ALS.FOUT(KIEZEN(VERT.ZOEKEN($C3;data!$C$1:$D$5;2;0);"ja";"nee");"")

 

[snb]

of

=IFERROR(INDEX({"ja";"nee"};INDEX(data!$D$2:$D$5;MATCH($C3;data!$C$2:$C$5;0));1);"")

 

[Friend]

JV,

Hartelijk dank voor je toelichting.

Helder, dat leert mij weer.

Friend

 

[Friend]

SNB

Hartelijk dank voor je reactie :thumb:

Waarschijnlijk doe ik het verkeerd maar de code geeft nu geen uitkomst



Heb alleen IFERROR aangepast naar ALS.FOUT

Friend

 

[JEC.]

Match naar vergelijken

 

[Friend]

JV,

Oeps die had ik over het hoofd gezien

Hartelijk dank,

Friend