Tekst invoegen in ALS formule

[masala09]

=ALS(EN(H6="JA";C12>0);TEKST("Postbus";"00000");(VERT.ZOEKEN(C12;'Database Klanten'!A:O;3;1);VERT.ZOEKEN(C12;'Database Klanten'!A:O;2;1))

Beste lezers. Bovenstaand een formule. Deze is fout. Daar was ik al achter, maar hoe moet deze dan wel.

Het is de bedoeling dat er bij ALS / EN is waar een postbusnummer wordt aangegeven. Nu had ik de formule kloppend, maar toen wilde ik voor het nummer nog de tekst: Postbus, hebben staan zodat de waarde i.p.v. de straatnaam bijvoorbeeld: Postbus 12345 wordt. Ik krijg het enkel voor elkaar met 12345.

De code die werkt zonder de tekst: Postbus, is als onderstaand:

=ALS(EN(H6="JA";C12>0);VERT.ZOEKEN(C12;'Database Klanten'!A:O;3;1);VERT.ZOEKEN(C12;'Database Klanten'!A:O;2;1))

Ik krijg het wel voor elkaar door een willekeurige cel de waarde: Postbus, te geven en deze samen te voegen. Dit is alleen niet wat ik wil.

Hierbij nog even die code en dan laat ik het erbij, want anders wordt het helemaal onoverzichtelijk.

=ALS(EN(H6="JA";C12>0);TEKST.SAMENVOEGEN(F6;(VERT.ZOEKEN(C12;'Database Klanten'!A:O;3;1)));VERT.ZOEKEN(C12;'Database Klanten'!A:O;2;1))

 

[plongske]

Probeer deze eens

=ALS(EN(H6="JA";C12>0);"postbus"&VERT.ZOEKEN(C12;Database Klanten!A$1:O$65536;3;1);"postbus"&VERT.ZOEKEN(C12;Database Klanten!A$1:O$65536;2;1))

 

[masala09]

Werkt niet. De directory waar dit bestand is opgeslagen wordt geopend.

Ik ga nu naar mijn mandje. Morgen, straks, weer vroeg dag.

 

[cow18]

="Postbus " & ALS(EN(H6="JA";C12>0);VERT.ZOEKEN(C12;'Database Klanten'!A:O;3;1);VERT.ZOEKEN(C12;'Database Klanten'!A:O;2;1))

 

[plongske]

Masala,
probeer deze eens,

=ALS(EN(H6="JA";C12>0);"postbus"&VERT.ZOEKEN(C12;'Database Klanten'!A:O;3;1);"postbus"&VERT.ZOEKEN(C12;'Database Klanten'!A:O;2;1))

 

[masala09]

Plongske toppie. Deze werkt.

Ik heb hem enkel een beetje aangepast. Ik was niet geheel duidelijk. Was nogal laat en had last van rechthoekige ogen.

Even voor de duidelijkheid.

Ik heb voor het opvragen van adresgegevens een aantal instellingen. Één ervan is "Adres met postbus". Hierop wordt via een voorwaarde uit een keuzelijst met: "Ja"of "Nee", bepaald of het normale verzendadres moet worden gebruikt of juist het postbusnummer uit de datalijst. Uiteraard geldt dit dan ook voor de postcode en plaats, maar daar hoeft niet de tekst "Postbus" voor te staan. Cel H6 op "Ja" EN cel C12 groter dan waarde 0 dan: "Postbus " "XXXXXX" staan. Cel H6 op "Nee" en Cel C12 groter dan waarde 0 dan GEEN tekst en enkel de straat en huisnummer. Echter als beide waarde leeg zijn, wat bij mij voor invoer het geval is dan komt er nog een ALS waarde bij. Om dit Dus daarmee volsta je dus al met:

Mede met jouw hulp heb ik de volgende werkende formule gemaakt.
Mede door jouw hulp is de volgende en voor mij gewilde formule tot stand gekomen.

=ALS(C12="";"";ALS(EN(H6="JA";C12>0);"Postbus "&VERT.ZOEKEN(C12;'Database Klanten'!A:O;5;1);VERT.ZOEKEN(C12;'Database Klanten'!A:O;2;1)))

Voor alle gevallen waar geen tekst "Postbus" hoeft te worden weergegeven zoals bij de bijbehorende postcode en plaats dan volsta je met:

=ALS(C12="";"";ALS(EN(H6="JA";C12>0);VERT.ZOEKEN(C12;'Database Klanten'!A:O;6;1);VERT.ZOEKEN(C12;'Database Klanten'!A:O;3;1)))

Cow18, ook jij bedankt voor jouw bijdrage. Jij had net als Plongske het zelfde idee en dat er in beide gevallen "Postbus " moest zijn te zien. Als dit het geval was dan was het beide juist.

 

[snb]

of ?

=ALS(C12="";"";ALS(H6="JA";"Postbus ";"") &VERT.ZOEKEN(C12;'Database Klanten'!A:O;5-ALS(H6="JA";0;3);1))

 

[plongske]

Had waarschijnlijk ook last van die rechthoekige ogen,plots waren de aanhalingstekens uit 'Database Klanten 'ervan tussen.