Tekst uit een cel halen wat begint met een #-teken

[8Leonie8]

Hallo excellers,

Ik heb al een tijdje gezocht in het forum, maar kom net niet tegen wat ik zoek.

Ik heb een kolom met daarin notities. In die notities staat soms een woord waar ik op wil rapporteren. Dit woord begint altijd met een # en is zonder spaties. Ik zoek nu een formule waarbij ik het woord met de # ervoor eruit kan halen. De woorden zijn niet allemaal even lang, en het kan zowel aan het begin, aan het eind of in het midden van de cel staan. Bijvoorbeeld:

- klant gebeld, vindt aanbieding te duur #teduur
- klant niet kunnen bereiken #vervallen klant reageert later toch, offerte gaat door
- aanbieding gaat door
- #vervallen

(ik heb de woorden waar het om gaat voor het beeld even vetgedrukt gemaakt, maar dit is in het excelbestand niet zo)

Wanneer er geen woord met een # in de kolom voorkomt, zou de cel leeg moeten blijven.

Wie kan mij helpen, of vertellen waar ik het antwoord kan vinden??? Alvast bedankt voor de hulp!

Groetjes Leonie

 

[arrie23]

Als in kolom A de tekst staat zet onderstaande formule dan in cel B1 en trek door naar beneden:

=ALS(ISFOUT(VIND.SPEC("#";A1));"";ALS(ISFOUT(MIDDEN(A1;VIND.SPEC("#";A1);VIND.SPEC(" ";A1;VIND.SPEC("#";A1))-VIND.SPEC("#";A1)));MIDDEN(A1;VIND.SPEC("#";A1);LENGTE(A1)-VIND.SPEC("#";A1)+1);MIDDEN(A1;VIND.SPEC("#";A1);VIND.SPEC(" ";A1;VIND.SPEC("#";A1))-VIND.SPEC("#";A1))))

Dit werkt alleen als er per regel maar 1 woord met het #-teken voorkomt

 

[8Leonie8]

Super, werkt helemaal! Ik moest alleen ivm mijn excelversie de woorden 'midden' vervangen door 'deel', nu werkt het perfect. Bedankt!

 

[Haaren101]

Werkt dat ook als het woord aan het eind van de regel staat? Dus als er geen " " achter het woord met de # komt?

Ron

Kan het niet uitproberen; heb een engelse versie hier

 

[8Leonie8]

Ik heb het even getest en voor de zekerheid eventuele spaties gedelete, maar het werkt ook als het woord aan het eind van de zin staat.

 

[arrie23]

Formule werkt als er nergens een #-woord staat (resultaat is "leeg"), als het #-woord aan het eind staat en als het #woord ergens middenin staat gevolgd door een spatie.

 

[Haaren101]

:thumb:

 

[snb]

Waarom niet gewoon vervangen ? ctrl H

vervang "#* " door ""

2e ronde

vervang "#*" door ""

 

[arrie23]

Beste snb, wellicht begrijp ik je oplossing niet helemaal maar het gaat er niet om dat die #-woorden weggehaald worden in de zin maar dat deze 'keywords' er juist uitgelicht worden en in een andere cel worden geplaatst

 

[snb]

Kijk, dat is een heel ander verhaal.
Dan zou ik een UDF gebruiken:

Function F_snb_001(c00)
    F_snb_001 = ""
    If InStr(c00, "#") Then F_snb_001 = Split(Split(c00, "#")(1))(0)
End Function

In bijv. cel B1
=F_snb_001(A1)

Maar met een 'gewone' formule zou ik deze aanraden:

=LEFT(MID(A3;FIND("#";A3);100);FIND(" ";MID(A3;FIND("#";A3);100)&" "))

=LINKS(DEEL(A3;VIND.SPEC("#";A3);100);VIND.SPEC(" ";DEEL(A3;VIND.SPEC("#";A3);100)&" "))

Van deze formule kun je een benoemd bereik maken, bijv. met de naam 'lemma'.
Dan hoef je in het werkblad alleen maar als formule op te geven: =lemma