Tekst vinden in bepaalde tekst

[witlofje]

Hallo,

Hoe kan ik in exel in een cel bepaalde tekst vinden en dan weergeven in een andere cel.
ik heb er ff een bestandje bij gedaan voor de duidlijkheid

 

[AHulpje]

In K4, doortrekken naar beneden:

=LINKS(DEEL(G4;5;99);VIND.SPEC(" ";DEEL(G4;5;99)))

 

[AlexCEL]

Voor de fun nog een paar.... (de laatste 2 alleen voor Excel 365)

=DEEL(G4;5;VIND.SPEC(" ";G4;6)-5)

=XML.FILTEREN("<t><s>"&SUBSTITUEREN(G4;" ";"</s><s>")&"</s></t>";"//s[2]")

=SPATIES.WISSEN(DEEL(SUBSTITUEREN(G4;" ";HERHALING(" ";9));9;9))

=TEKST.VOOR(TEKST.NA(G4;" ";1);" ")

=INDEX(TEKST.SPLITSEN(G4;" ");2)

Als alles in hoofdletters moet zet je functie HOOFDLETTERS er nog omheen...

 

[witlofje]

Heel af en toe gebeurt het ook dat de wat in kolom k moet komen te staan ook wel eens als eerste staat, dus: RDL 3kg RLDS DPA hierbij moet dus RDL in de kolom k komen te staan.
is dit ook te combineren in een formule?

 

[AlexCEL]

Hoe kan ik weten dat het eerste woord gezocht wordt en niet het tweede?

 

[witlofje]

Dat kun je niet weten, dat zijn regels die ik zo binnen krijg.
Is er niet een formule die kijkt naar krm of krg of lang of rdl? Ze komen nooit dubbel voor in de regel

 

[AlexCEL]

Kunnen alleen die woorden voorkomen? Dan kan ik het WEL weten...

Bijv.

=KIEZEN(MAX(ISGETAL(VIND.SPEC({"KRM";"KRG";"RDL";"lang"};G4))*{1;2;3;4});"KRM";"KRG";"RDL";"LANG")

Mogelijk afsluiten met Control+Shift+Enter als je geen Excel 365 gebruikt.

 

[witlofje]

Er zijn nog een paar afkortingen, food, XKT

 

[AlexCEL]

Die kun je nu zo toevoegen toch?

Gebruik je Excel 365?

 

[witlofje]

ja gelukt, alleen als er niets in de tekst kolom staat krijg ik allemaal hekjes, is dat ook nog op te lossen?

 

[AlexCEL]

Zo bijv.

=ALS.FOUT(KIEZEN(MAX(ISGETAL(VIND.SPEC({"KRM";"KRG";"RDL";"lang"};G4))*{1;2;3;4});"KRM";"KRG";"RDL";"LANG");"")

Hier nog ééntje voor Excel 365:

=LET(x;{"KRM";"KRG";"RDL";"LANG";"FOOD";"XKT"};FILTER(x;ISGETAL(VIND.SPEC(x;G4));""))

 

[witlofje]

Top, het werkt perfect.
Heel erg bedankt voor de moeite, zo kan ik weer verder.