Termijn vraag

[NESJA]

Goedemiddag

Voor het maken van bestellingen hou ik een excellijst bij. (Blad 1 en Blad 2)
Deze lijst bevat een datum een plaatsnaam en een categorie (groot, middel of klein)
Nu wil ik dat ik kan op een makkelijke manier kan zien of ik weer moet bestellen.
Ik moet bestellen als er 16 weken na de datum van vandaag geen bestelling meer in mijn lijst voorkomt.
Voor Boxmeer zie ik bijvoorbeeld dat ik niks meer in de bestelling heb staan.

Hopelijk is mijn vraag duidelijk en kan iemand mij helpen.

Bijgaand het bestand.Bekijk bijlage Vraag.xlsx

Gr NESJA

 

[AlexCEL]

Zoek je dit wellicht (voor B2 op blad1):

=ALS(AANTALLEN.ALS(Blad2!$B$2:$B$31;$A2;Blad2!$C$2:$C$31;B$1;Blad2!$A$2:$A$31;">="&VANDAAG()+16*7)=0;"bestellen";"")

 

[NESJA]

HOi Alexcel,

dit is inderdaad bijna wat ik zoek, is het ook mogelijk om ipv een lege cel te zien, waar het goed staat, ik dan het aantal te zien krijg

Dit zodat ik weet hoeveel er nog loopt.

Gr. NESJA

 

[AlexCEL]

Zo goed?

=ALS(AANTALLEN.ALS(Blad2!$B$2:$B$31;$A2;Blad2!$C$2:$C$31;B$1;Blad2!$A$2:$A$31;">="&VANDAAG()+16*7)=0;"bestellen";AANTALLEN.ALS(Blad2!$B$2:$B$31;$A2;Blad2!$C$2:$C$31;B$1))

 

[NESJA]

AlexCel
ik dacht dat de formule van hierboven juist bleek te zijn. Dit is echter niet zo.
Wat ik nu zie is dat de formule het volgende doet.
Als er niet besteld hoeft te worden dan telt hij ook de bestellingen verleden erbij op
Zo geeft hij bijvoorbeeld bij Amsterdam Groot het aantal 3, dit moeten er echter 2 zijn.
Zie jij waar de fout in de formule zit, ik heb t proberen te achterhalen maar ik kom er niet uit.
GR NESJA

 

[AlexCEL]

Aanpassingen:
1. "Als er niet besteld hoeft te worden dan telt hij ook de bestellingen verleden erbij op." → Formule is nu aangepast zodat alleen bestellingen na VANDAAG worden meegenomen.
2. Vraag via privé-bericht (mag gewoon via forum): "... (is) het ook mogelijk is om in de formule een deel van een woord te tellen. Bijvoorbeeld voor het woord Groot, dat ik dan alleen de G gebruik. Ik heb namelijk nog meer variaties met Groot." → Formule kijkt nu naar eerste letter.

=ALS(SOMPRODUCT((Blad2!$B$2:$B$31=$A2)*(LINKS(Blad2!$C$2:$C$31;1)=LINKS(B$1;1))*(Blad2!$A$2:$A$31>=(VANDAAG()+16*7)))=0;"Best.";SOMPRODUCT((Blad2!$B$2:$B$31=$A2)*(LINKS(Blad2!$C$2:$C$31;1)=LINKS(B$1;1))*(Blad2!$A$2:$A$31>=VANDAAG())))

De formule wordt niet simpeler of sneller van de aanpassingen...

 

[NESJA]

Goedemiddag,

Op één of andere manier werkt de formule niet bij mij als ik m in mijn eigen bestand plaats.
Vandaar dat ik nu een aangepast bestand plaats die dezefde opmaak heeft als mijn eigen bestand.
Daarnaast ben ik er achter gekomen dat ik ook een aantal bestellingen heb die vervallen zijn na 16 weken na vandaag.
Helaas telt hij deze volgens mij dan alsnog mee. Dit zie je doordat er in kolom M ipv een 1 een 0 staat.
Is hier ook een formule voor.
Ik begrijp dat het niet slim is om tijdens het posten van de vraag met nieuwe vragen te komen maar in het kader van aldoende leert men, hopelijk iemand die mij kan helpen.
Voor de duidelijkheid op blad 1 kolom B, M en K wil ik alles met één letter en de overige kolommen wil ik graag het per soort bestelling zoals GR1 of MID (uiteraard uitsluitend voor de bestellingen van 16 weken of later na vandaag)

En last but not least bedankt AlexCel voor de moeite die je hebt genomen!

Bijgaand het aangepaste bestand.Bekijk bijlage Overzicht bestelling.xlsx
GR. NESJA

 

[AlexCEL]

Een opzetje in bijlage. Ik weet niet precies wat je als uitkomst bij GR1,2,3,.. etc. verwacht. Je zult zelf alle voorwaarden even bij langs moeten gaan, hopelijk lukt dat met bijlage. Misschien dat een draaitabel met een paar filters nu ook wel een optie wordt. De formule wordt ingewikkeld en de lijst is lang.

 

[NESJA]

Hoi AlexCEL,

Bedankt voor het overzicht. Ik heb t nagekeken en ik zie helaas dat hij nog niet doet wat ik wil.
Ik zal Alkmaar als voorbeeld nemen. Vandaag 9-4-2020 zijn er de volgende bestellingen die na de 16 weken liggen (volgens het tabblad bestelling;
6-8-2020 augustus 32 do Middag GR2 Alkmaar
7-8-2020 augustus 32 vr Middag GR1 Alkmaar
7-8-2020 augustus 32 vr Ochtend MID1 Alkmaar
11-8-2020 augustus 33 di Ochtend GR1 Alkmaar
21-8-2020 augustus 34 vr Ochtend MID1 Alkmaar
24-8-2020 augustus 35 ma Middag GR1 Alkmaar

De telling op blad1 geeft het volgende aan;
G: 15
GR1: 7
GR2: 8
M: 6
MID1: 6

Volgens mij moet er nu in het overzicht komen te staan
G: 4
GR1: 3
GR2: 1
M: 2
MID1: 2

Ik heb de formule geëvalueerd en het lijkt erop dat hij een ander getal teruggeeft (via Formules--> Formule evalueren):
De formule van B2 in blad1 heb ik geëvalueerd;
Na 35x op "Evalueren" te klikken, krijg ik o.a. dit te zien (excuus ik weet niet hoe ik dit anders moest verwoorden;
=ALS(4=0;"B";SOMPRODUCT.......
Volgens mij is die 4 het juiste cijfer dat ik nodig heb en dit komt ook overeen, met hetgeen hierboven
Op het eind van de evaluatie staat er 15, maar dit is getal is onjuist.

Voor de formule van cel C2 in blad1 heb ik hetzelfde,
Na 11x op "Evalueren" te klikken, krijg ik o.a. te zien;
=ALS(3=0;"B";AANTALLEN.ALS.....
Ook hier denk ik dat die 3 het juiste cijfer is. IPV het cijfer 7. Die 3 komt ook overeen met hetgeen hierboven.

Ik ben me ervan bewust dat dit een hele lap tekst is hopelijk kan iemand aangeven hoe ik het juiste cijfer op de juiste plek krijg.

GR. NESJA

 

[sylvester-ponte]

NESJA, kun je de filters in blad bestelling zo zetten dat jouw uitkomsten duidelijk zijn? en dan dat bestand hier plaatsen?

 

[NESJA]

Goedemiddag

Bijgaan het bestand met mijn filters. 16 weken komt uit op 31-7. zie Cel O1 en P1.
Bekijk bijlage Overzicht bestelling (NEJSA).xlsx
Gr. NESJA

 

[NESJA]

Ik ben er gelukkig achtergekomen waar de fout zit;
in Blad1 CelB2 staat als formule:

=ALS(SOMPRODUCT((bestelling!$H$2:$H$2011=$A2)*(LINKS(bestelling!$G$2:$G$2011;1)=LINKS(B$1;1))*(bestelling!$M$2:$M$2011=1)*(bestelling!$A$2:$A$2011>=(VANDAAG()+16*7)))=0;"B";SOMPRODUCT((bestelling!$H$2:$H$2011=$A2)*(LINKS(bestelling!$G$2:$G$2011;1)=LINKS(B$1;1))*(bestelling!$M$2:$M$2011=1)*(bestelling!$A$2:$A$2011>=VANDAAG())))

Het stukje op het eind ontbreekt, waardoor de formule ging kijken naar alle bestellingen vanaf vandaag, ik heb m hieronder met een grote lettertype geplaatst, nu is de formule wel juist

=ALS(SOMPRODUCT((bestelling!$H$2:$H$2011=$A3)*(LINKS(bestelling!$G$2:$G$2011;1)=LINKS(B$1;1))*(bestelling!$M$2:$M$2011=1)*(bestelling!$A$2:$A$2011>=(VANDAAG()+16*7)))=0;"B";SOMPRODUCT((bestelling!$H$2:$H$2011=$A3)*(LINKS(bestelling!$G$2:$G$2011;1)=LINKS(B$1;1))*(bestelling!$M$2:$M$2011=1)*(bestelling!$A$2:$A$2011>=VANDAAG()+16*7)))

Het stukje +16*7 ontbreekt volgens mij ook in de andere formules.

De vraag is bij deze opgelost, dank voor al jullie hulp!
GR NESJA

 

[sylvester-ponte]

jouw filter staat op augustus , was dat de bedoeling?

 

[NESJA]

Dat klopt inderdaad, dit komt omdat er geen bestellingen verder in de toekomst dan in de maand augustus liggen, voor Alkmaar.
Ik had namelijk eerst alle filters gewist. Vervolgens alle datums geselecteerd vanaf 31/7, toen het filter op Alkmaar gezet.