Unieke waarden tellen wanneer andere cel in zelfde rij is ingevuld

[FairyQueen1988]

Hoi allemaal

Ik ben al een hele tijd op zoek naar een formule om het aantal personeelsleden te tellen in verschillende instellingnummers van onze scholen.
Het totaal aantal personeelsleden (unieke waarden) kon ik al trekken door de volgende formule:

=SOMPRODUCT(1/AANTALLEN.ALS(A5:A140;A5:A140;B5:B140;B5:B140))

Nadien heb ik het met een andere (meer eenvoudige) formule geprobeerd door de namen eerst samen te voegen (in kolom C) waardoor ik het ook met de volgende formule kon bereiken:

=AANTALARG(UNIEK(C5:C140))

. Veel korter dus.

Maar nu zocht ik nog een manier om de aantal ingeschreven personeelsleden per school te tellen (die dus een opdracht hebben in de instellingnummers 016667, 016675 en 048355). Liesbet Wielockx heeft bijvoorbeeld een opdracht in twee scholen (016667 en 016675) maar komt ook meerdere keren voor in kolom A/B omdat het om meerdere soorten opdrachten gaat. Ze mag dus zowel in 016667 als in 016675 meegeteld worden.

Ik ging ervan uit dat ik dus eerst moest controleren of er voor 016667 kolom E ingevuld is. Voor 016675 moet ik dus in kolom H en K kijken en voor 048355 in kolom N.
Ik benoem nu specifiek de kolommen waarin de cellen teksten bevatten. De kolommen erlangs bevatten de uren van hun opdrachten, dus het maakt uiteindelijk niet uit welke kolom ik zou nemen hiervoor.

Ik heb het al eens met de volgende formules geprobeerd voor 016667, maar ik kom hierbij telkens 31,5 uit, wat duidelijk niet kan kloppen.

=SOMPRODUCT(ALS(ISLEEG(E$5:E$140);"";1/AANTALLEN.ALS(A5:A140;A5:A140;B5:B140;B5:B140)))
=SOMPRODUCT(ALS(AANTAL.ALS(E5:E140;E5:E140)=0;"";1/AANTALLEN.ALS(A5:A140;A5:A140;B5:B140;B5:B140)))

Ik probeerde ook al met de formule UNIEK ipv AANTALLEN.ALS, maar dat geeft dan weer 4628??

Kan iemand mij helpen met hoe ik dit toch kan berekenen? Ik zie het even niet meer

 

[lam201]

Zo misschien?

voor 01667:

=AANTAL.ALS(F5:F125;">0")

eventueel bereik aanpassen.

 

[FairyQueen1988]

Het is jammer genoeg complexer dan dat, aangezien de personeelsleden vaak tot driedubbel voorkomen. Daarmee dat ik het wou combineren met de formule UNIEK (ofzo)

 

[AlexCEL]

Kun je een geanonimiseerd of goed gelijkend voorbeeldbestand met dummy data plaatsen i.p.v. een plaatje? Dan valt het e.e.a. uit te proberen.

 

[lam201]

aha. dan deze

=AANTALARG(UNIEK(FILTER(C5:C125;F5:F125>0)))

en anders toch even dat voorbeeldbestand uploaden

 

[FairyQueen1988]

Wel, dat is de formule dat ik zocht
Ik heb nog wat gezocht aan de hand van deze formule of ik de twee kolommen van 16675 (211 en 111) kon combineren met een OF functie.
Dat is toch nog niet geslaagd

Ik zal een dummie-document toevoegen in bijlage zoals jullie vragen.

Alvast heel erg bedankt om mee na te willen denken! :love:

 

[AlexCEL]

Een simpele oplossing voor W32:

=AANTALARG(UNIEK(FILTER(C5:C29;(H5:H29>0)+(K5:K29>0))))

Criteria optellen in de FILTER-functie staat gelijk aan een OF-functie. Vermenigvuldigen is een EN-functie.

PS ook nog een alternatief voor W34:

=AANTALARG(UNIEK(A6:A29&B6:B29))

 

[FairyQueen1988]

Ooh fijn! Dank je wel! Het werkt allemaal nu! Dank je wel allemaal voor de tips :love: