Userform aanpassen

[bowlingman]

Hallo,
Ik ben testjes aan het uitvoeren met een Userform.
De achtergrond heb ik een kleur gegeven.
Bovenaan krijg je dan een witte boord met daarin het rode kruisje om af te sluiten.
Kan je ergens in de opmaak instellen dat deze witte boord dezelfde kleur heeft als de achtergrond van het form of eventueel deze boord volledig weglaten.

Grtjs.
Armand

 

[edmoor]

Dat kan. Plaats het volgende in een module (32-bit Office):

Option Explicit

Private Declare Function FindWindow Lib "User32" _
Alias "FindWindowA" ( _
ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long

Private Declare Function GetWindowLong Lib "User32" _
Alias "GetWindowLongA" ( _
ByVal hwnd As Long, _
ByVal nIndex As Long) As Long

Private Declare Function SetWindowLong Lib "User32" _
Alias "SetWindowLongA" (ByVal hwnd As Long, _
ByVal nIndex As Long, _
ByVal dwNewLong As Long) As Long

Private Declare Function DrawMenuBar Lib "User32" ( _
ByVal hwnd As Long) As Long

Sub RemoveTitleBar(frm As Object)
    Dim lStyle          As Long
    Dim hMenu           As Long
    Dim mhWndForm       As Long
     
    mhWndForm = FindWindow("ThunderDFrame", frm.Caption)
    lStyle = GetWindowLong(mhWndForm, -16)
    lStyle = lStyle And Not &HC00000
    SetWindowLong mhWndForm, -16, lStyle
    DrawMenuBar mhWndForm
End Sub

En dit achter het Userform:

Private Sub UserForm_Initialize()
    Call RemoveTitleBar(Me)
End Sub

N.B.:
Vergeet niet een Sluit knop aan het userform toe te voegen

 

[bowlingman]

Super Ed,

Werkt perfect.
Bedankt en de beste wensen voor 2018

Grtjs.
Armand

 

[edmoor]

Hetzelfde gewenst Armand