userform met automatisch volgende projectnummer

[Warme bakkertje]

In Post#15 geef ik je alle werkende code die je enkel in je UF moet plaatsen, maar je doet er niets mee.
Wat kan er makkelijker zijn dan kopieëren en plakken ????
Onderstaande versie aangepast aan je nieuwe UF-ontwerp. Doe er deze keer iets mee.

Private Sub Userform_Initialize()
    
    With Sheets("Projecten")
        txtProjNr.Text = WorksheetFunction.Max(.Range("B2:B" & .Cells(.Rows.Count, 2).End(xlUp).Row)) + 1
    End With
    
End Sub

Private Sub cmdSubmit_Click()
    
    With Sheets("Projecten")
       .Range("A" & .Rows.Count).End(xlUp)(2).Resize(, 3) = Array(txtProjNaam.Text, txtProjNr.Text, txtProjLand.Text)
    End With

End Sub

Private Sub cmdClearFields_Click()
    
    For Each ctl In Controls
        If TypeName(ctl) = "TextBox" Then
            ctl.Text = vbNullString
        End If
    Next

End Sub

Private Sub cmdCancel_Click()
    
    Unload Me

End Sub

 

[wernervanstrien]

Dank warm Bakkertje,

Sorry voor je dubbele werk! Onwetend en onkundig mijnerzijds.

Ga het copie pasten en uiteindelijk ook begrijpen. Heb nu boek vba voor dummies in huis!

Heb jij misschien nog een goed boek als tip?

 

[wernervanstrien]

Warm Bakkertje,

Super bedankt het werkt. In mijn vorige opzet had ik de datum die automatisch werd doorgevoerd. Daarvoor had ik de volgende lijn er nog tussen staan: Sheets("Projecten").Cells(nextrow, 4) = Now, dit was een veld wat je niet invulde, maar wat er automatisch kwam te staan na 'submit' te klikken. Ik heb geprobeerd die er tussen te zetten, maar dat werkt niet. Hoe pas ik deze nog in?

En is het mogelijk dat ipv 'clear fields', de 'submit' button er voor zorgt dat alles schoon wordt met het volgende nummer er al in?

U zijt geweldig nu al, met oplossing voor bovenstaande een Godheid!

Zonder gekheid: DANK!

Werner

 

[Warme bakkertje]

Dit was nu toch niet zo moeilijk om zelf uit te vogelen, nietwaar ?

Private Sub cmdSubmit_Click()
    
    With Sheets("Projecten")
       .Range("A" & .Rows.Count).End(xlUp)(2).Resize(, 4) = Array(txtProjNaam.Text, txtProjNr.Text, txtProjLand.Text, Format(Date, "mm/dd/yyyy"))
    End With
    For Each ctl In Controls
        If TypeName(ctl) = "TextBox" Then
            ctl.Text = vbNullString
        End If
    Next
    With Sheets("Projecten")
        txtProjNr.Text = WorksheetFunction.Max(.Range("B2:B" & .Cells(.Rows.Count, 2).End(xlUp).Row)) + 1
    End With
    
End Sub

 

[wernervanstrien]

Hee Warm Bakkertje,

Misschien niet, had wat getest, echter ik kreeg het niet voor elkaar om het nummer +1 dan meteen alweer in het formulier te houden, zodat ik meteen door kan met de voglende invoer en niet nog eens het nummer hoef in te voeren.

De datum laat ie ook zien als 2-7-2013 00:00. Hij zet de tijd dus op 0 steeds.

Suggesties? Dank.

W.

 

[Warme bakkertje]

Private Sub cmdSubmit_Click()
    
    With Sheets("Projecten")
       .Range("A" & .Rows.Count).End(xlUp)(2).Resize(, 4) = Array(txtProjNaam.Text, txtProjNr.Text, txtProjLand.Text, Format(DateTime.Now, "mm/dd/yyyy hh:mm:ss"))
    For Each ctl In Controls
        If TypeName(ctl) = "TextBox" Then
            ctl.Text = vbNullString
        End If
    Next
        txtProjNr.Text = WorksheetFunction.Max(.Range("B2:B" & .Cells(.Rows.Count, 2).End(xlUp).Row)) + 1
    End With
    
End Sub