userform steeds op dezelfde plaats laten verschijnen

[starchaser]

Hallo iedereen,

Ik ben me momenteel aan het verdiepen in het gebruik van userforms. Nog een vrij nieuwe materie voor me, maar stap voor stap zal het wel lukken.

Ik wil graag een userform direct laten opstarten bij het openen van mijn excelbestand én steeds op dezelfde plaats (liefst nog dat de gebruiker deze niet kan verplaatsen.

Het automatisch openen is me ondertussen gelukt (userform.show), maar de vaste plaats nog niet.

Kan dit wel?

bedankt voor de info
grtn
Starchaser

 

[SjonR]

Dat kan hiermee worden ingesteld of bij de eigenschappen in je userform (top,Left)

Private Sub UserForm_Activate()
 
    Me.Top = 200
    Me.Left = 100

End Sub

Voor het in het midden vastzetten vond ik deze op een ander forum en dat werkt goed:

Option Explicit
 
Private m_sngAnchorLeft As Single
Private m_sngAnchorTop As Single
Private m_blnSetAnchor As Boolean
Private Sub UserForm_Activate()
    If Me.Visible Then
        If Not m_blnSetAnchor Then
            m_sngAnchorLeft = Me.Left
            m_sngAnchorTop = Me.Top
            m_blnSetAnchor = True
        End If
    End If
End Sub
 
Private Sub UserForm_Deactivate()
     
    m_blnSetAnchor = False
     
End Sub
 
Private Sub UserForm_Layout()
     
    If m_blnSetAnchor Then
        Me.Left = m_sngAnchorLeft
        Me.Top = m_sngAnchorTop
    End If
     
End Sub

 

[starchaser]

Sjonr,

Bedankt voor je oplossing. Code toegevoegd en nu kan ik mijn userform steeds op dezelfde plaats laten verschijnen.

grtz
Starchaser

 

[HSV]

En verwijder 'Me.'.