Vanuit Access taak in Outlook toewijzen aan collega

[btl]

Hallo,

Ik ben bezig om vanuit Access een taak aan te maken in Outlook. Dit is prima mogelijk in je eigen takenlijst of in de takenlijst van een specifiek iemand. Hiervoor gebruik ik de volgende code:

Option Compare Database


Private Sub Knop21_Click()

DoCmd.RunCommand acCmdSaveRecord
' Exit the procedure if appointment has been added to Outlook.
If Me!addedtooutlook = True Then
MsgBox "This appointment already added to Microsoft Outlook"
Exit Sub
' Add a new appointment.
Else

Dim NowDate As Date
Dim DateEnd As Date
Dim DateDif As Long
Dim Task As Object
Dim ToContact As Object

Set Task = Outlook.CreateItem(olTaskItem)
NowDate = Now()
DateEnd = Apptdate

If DateAdd("d", -1, DateEnd) >= 1 Then
DateEnd = DateAdd("d", -1, DateEnd)
Else
End If

Task.Subject = Apptnotes
Task.Body = "Bekijk het complete verslag in de database."
Task.Assign
Set ToContact = Task.Recipients.Add("jij@wij.nl")
Task.DueDate = DateEnd
Task.Importance = (olImportanceHigh)
Task.ReminderSet = True
Task.Save

End If

End Sub


Maar in plaats van een vast emailadres in de code op te nemen (jij@wij.nl) wil ik dat deze verwijst naar een in het formulier/tabel in te vullen emailadres. Dit lukt me echter niet en kan online ook geen codes vinden hiervoor.

Alvast bedankt!

 

[OctaFish]

Je zit in het verkeerde forum, want zo te zien gebruik je Access als programma en dan gebruik je VBA als programmeertaal en niet Visual Basic .Net. Daarnaast heb je zo te zien wél een verwijzing opgenomen naar de Outlook bibliotheek, maar gebruik je een Object variabele en geen Outlook object. En wat doet die Set ToContact?
Verder doe je jezelf tekort, want je aanpak is Late Binding en je techniek Early Binding. Ik zou zeggen: kies voor de één of de ander!

Ik heb nu even geen Access tot mijn beschikking, dus ik heb een beetje gegokt en de Check er even uitgegooid. Maar die doet verder niet zoveel bijzonders....

Function OutlookTask()
Dim NowDate As Date, DateEnd As Date
Dim Task As Outlook.TaskItem
    
    Set Task = Outlook.CreateItem(olTaskItem)
    NowDate = Now()
    DateEnd = NowDate + 7
    If DateAdd("d", -1, DateEnd) >= 1 Then
        DateEnd = DateAdd("d", -1, DateEnd)
    End If
    With Task
        .Subject = Me.ApptNotes
        .Body = "Bekijk het complete verslag in de database."
        .Assign
        .Recipients.Add Me.Emailadres
        .DueDate = DateEnd
        .Importance = (olImportanceHigh)
        .ReminderSet = True
        .Save
    End With
    
End Function

 

[btl]

Dank voor de ondersteuning alvast en ik twijfelde al waar ik het beste bij kon zetten. Ik verplaats het even naar het goede forum!