Variabele opmaak via macro

[Georgyboy]

Goeiedag,

Graag had ik een macroknop aangemaakt voor een opmaak in excel.
Meestal heb ik dezelde opmaak. Namelijk lichtgrijze binnenkader, bovenste rij gecentreerd vet,arcering groen, etc.

Via een macro gaat dit, doch altijd op hetzelfde bereik, indien op een andere plaats en/of met meer of minder rijen of kolommen, dan klopt dit helemaal niet meer.

Wie kan me verder helpen?

 

[Demeter]

mmmmmmmmmm, daar moet wat meer tijd in gaan zitten.
Misschien kan ik morgen met iets op de kroppen komen, nu weinig prive tijd.

Wel iets aan je code gesleuteld:

Sub Knop2_BijKlikken()

Range("A1:E17").Select
    With Selection.Borders
        .Weight = xlMedium
    End With

    With Selection.Borders(xlInsideVertical)
        .Weight = xlThin
        .ColorIndex = 48
    End With
    
    With Selection.Borders(xlInsideHorizontal)
        .Weight = xlThin
        .ColorIndex = 48
    End With
    
Range("A1:E1").Select
    With Selection
        .Borders.Weight = xlThin
        .Font.Bold = True
        .Interior.ColorIndex = 35
    End With
    
End Sub

Is een opzetje hoe je het allemaal wat overzichtelijker kan maken.
Alleen je dikke lijn op je 1e regel is nu tijdelijk weg.

Komt morgen allemaal wel goed.

Groet,
Ferenc

 

[Wigi]

Code van Demeter nog wat verbeterd qua With statement.

Sub Knop2_BijKlikken()

    With Range("A1:E17")
        With .Borders
            .Weight = xlMedium
        End With
        
        With .Borders(xlInsideVertical)
            .Weight = xlThin
            .ColorIndex = 48
        End With
        
        With .Borders(xlInsideHorizontal)
            .Weight = xlThin
            .ColorIndex = 48
        End With
    End With
        
    With Range("A1:E1")
        .Borders.Weight = xlThin
        .Font.Bold = True
        .Interior.ColorIndex = 35
    End With
End Sub

En nu terug m'n bed in want nog ziek

Wigi

 

[Demeter]

Met dank aan onze vrienden op Ozgrid (http://www.ozgrid.com/forum/showthread.php?p=328661):

Sub Button_1()

    With Selection
        With .Borders
            .Weight = xlMedium
        End With
        
        With .Borders(xlInsideVertical)
            .Weight = xlThin
            .ColorIndex = 48
        End With
        
        With .Borders(xlInsideHorizontal)
            .Weight = xlThin
            .ColorIndex = 48
        End With
    End With
        
    With Selection.Rows(1)
        .Borders.Weight = xlMedium
        .Font.Bold = True
        .Interior.ColorIndex = 35
        
        .Borders(xlInsideVertical).Weight = xlThin
        .Borders(xlInsideVertical).ColorIndex = 48
    End With
    
End Sub

Groet,
Ferenc