Vast emailadres in bestand

[Inekebeu]

Goedenavond,

Maandelijks sturen we altijd dezelfde (basis) bestanden met bijgewerkte gegevens per email naar onze klanten. Is het mogelijk in het excelbestand zelf het emailadres van deze klant op te nemen en het bestand aldus op te slaan? Ik meende dit ongeveer een jaartje geleden ontdekt te hebben, maar voordat ik dit verder uit kon werken, stonden er veel drukke(re) en urgentere dingen op het programma. M.i. kon dat toen via verzenden/circulatielijst, maar we werkten toen met excel 2000 en nu 2007 en daar kan ik dat niet meer terugvinden.
Weet iemand of dat kan, en zo ja, hoe ik dat moet inregelen in excel 2007?

Alvast bedankt.

Mvg
Ineke

 

[koosl]

Ineke,

op de site van Ron de Bruin staan verschillende codes.
http://www.rondebruin.nl/mail/folder1/mail5.htm

Deze hieronder komt daar ook vandaan. Alle lof en dank dus naar Ron.


Er wordt gemaild naar de geadresseerde uit cel A1

Sub Mail_Every_Worksheet()
    'Working in 97-2007
    Dim sh As Worksheet
    Dim wb As Workbook
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim TempFilePath As String
    Dim TempFileName As String
 
    TempFilePath = Environ$("temp") & "\"
 
    If Val(Application.Version) < 12 Then
        'You use Excel 97-2003
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        'You use Excel 2007
        FileExtStr = ".xlsm": FileFormatNum = 52
    End If
 
    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With
 
    For Each sh In ThisWorkbook.Worksheets
        If sh.Range("A1").Value Like "?*@?*.?*" Then
 
            sh.Copy
            Set wb = ActiveWorkbook
 
            TempFileName = "Sheet " & sh.Name & " of " _
                         & ThisWorkbook.Name & " " & Format(Now, "dd-mmm-yy h-mm-ss")
 
            With wb
                .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
                On Error Resume Next
                .SendMail sh.Range("A1").Value, _
                          "This is the Subject line"
                On Error GoTo 0
                .Close SaveChanges:=False
            End With
 
            Kill TempFilePath & TempFileName & FileExtStr

        End If
    Next sh
 
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

Koosl.

 

[Inekebeu]

Bedankt Koos voor je reactie en voor de link naar Ron's site, want daar staan heel nuttige dingen op. Heb vandaag al wat kunnen testen en dat werkte prima. Ga volgende week weer verder, eerst weekend.

groet
Ineke