VBA: gegevens van webpagina kopieëren en plakken als tekst

[Conseclusie]

Hallo,

Ik ben op zoek naar VBA-code voor het volgende:
Via onderstaande macro open ik een bepaalde webpagina:

Sub OpenTeletekst()
sPath = "C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe" 'my browser = Edge
sURL = "https://teletekst-data.nos.nl/webplus?p=" & "101"
dTaskID = Shell(sPath & " " & sURL, vbNormalFocus)
End Sub

Vervolgens kopieër ik (handmatig) de volledige pagina (via <CTRL> + a , <CTRL> + c) en plak ik deze inhoud in een excel-blad (via Plakken Speciaal / Tekst).
Is dit volledige proces in een VBA-code te vangen?

 

[alphamax]

Basiscode

Option Explicit

Public Sub Teletekst()
    Dim sResponseText As String
    With CreateObject("msxml2.xmlhttp")
        .Open "GET", "https://teletekst-data.nos.nl/webplus?p=101", False
        .Send
        sResponseText = .responsetext
        With CreateObject("htmlfile")
            .Write sResponseText
            MsgBox .getElementsByTagName("pre")(0).innertext
        End With
    End With
End Sub

 

[alphamax]

Dit komt meer overeen met je gestelde vraag uit bericht#1.

In Module Blad1.

Option Explicit

Public Sub Teletekst2()
    Dim aLines As Variant
    Dim sResponseText As String
    Range("A1").CurrentRegion.ClearContents
    With CreateObject("msxml2.xmlhttp")
        .Open "GET", "https://teletekst-data.nos.nl/webplus?p=101", False
        .Send
        sResponseText = .responsetext
        With CreateObject("htmlfile")
            .Write sResponseText
            aLines = Application.Transpose(Split(.getElementsByTagName("pre")(0).innertext, vbCrLf))
            Range("A1").Resize(UBound(aLines, 1), 1) = aLines
        End With
    End With
    Range("A1").CurrentRegion.Columns.AutoFit
End Sub

 

[Conseclusie]

Wow!! Ik dacht eerlijk gezegd dat het zonde van m'n tijd was om deze vraag uberhaubt te stellen, omdat ik er van overtuigd was dat het toch niet mogelijk was.... Maar dit werkt echt perfect!
Enorm bedankt Alphamax!

 

[Conseclusie]

...voor mijn specifieke vraag werkt het inderdaad correct.
Maar het lijkt niet voor iedere willekeurige pagina te werken.
Bij

https://eredivisie.nl/nl-nl/Wedstrijden/Wedstrijdoverzicht/id/2119324

krijg ik foutmelding bij

aLines = Application.Transpose(Split(.getElementsByTagName("pre")(0).innertext, vbCrLf))

"Fout 91 tijdens uitvoering: Objectvariabele of blokvariabele With is niet ingesteld."
Wat ik vreemd vind, aangezien enkel de URL anders is...
Maar ja,....dit is ook hogeschool VBA voor me.

 

[alphamax]

Voor elke URL kan

aLines = Application.Transpose(Split(.getElementsByTagName("pre")(0).innertext, vbCrLf))

totaal anders zijn.
Deze code gaat op zoek naar PRE-tags in de HTML code van de teletekst pagina.
Deze technieken heten "webscraping", google er maar eens op.

 

[Conseclusie]

Ga ik doen. Dank voor de extra info!