vba kijken of een schijf aanwezig is.

[Robert Smidt]

Beste Helpmij'ers,

Ik ben op zoek naar een code - vanuit excel (vba) - of een schijf aanwezig is.

Ik kan zelf in een cel aangeven waar ik mijn backup wil plaatsen. De cel heb ik de naam "Backupdrive" meegegeven en ik kan daar kiezen uit de schijven: C:\, D:\, E:\, F:\, G:\ en H:\. Doorgaans kies ik voor H:\ echter wil ik wel eens vergeten om de stick te plaatsen en krijg dan een foutmelding. Mijn verzoek is dat deze in dat geval het programma verlaat (exit sub) en de melding geeft dat de gekozen schijf niet is gevonden en het programma verlaat.

Alvast heel erg bedankt.

Robert

 

[alphamax]

[SIZE=1]Option Explicit

Public Sub DriveExists()
    Dim strDriveName As String
        strDriveName = "c"
        With CreateObject("Scripting.FileSystemObject")
            If Not .DriveExists(strDriveName) Then
                MsgBox strDriveName & "-drive exists not."
            ElseIf .GetDrive(strDriveName).IsReady Then
                MsgBox strDriveName & "-drive exists and is ready."
            Else
                MsgBox strDriveName & "-drive exists and is not ready."
            End If
        End With
End Sub[/SIZE]

 

[OctaFish]

Of zo:

Sub test()
    MsgBox CheckDir("J:\")
End Sub

Function CheckDir(pad As String) As Boolean
Dim myName As String
    myName = Dir(pad, vbDirectory)
    Do While myName <> ""
        If myName <> "." And myName <> ".." Then
            If (GetAttr(pad & myName) And vbDirectory) = vbDirectory Then
                CheckDir = True
                Exit Function
            End If
        End If
        myName = Dir
    Loop
    CheckDir = False
End Function

 

[Robert Smidt]

De code werkt, heel erg bedankt voor jullie hulp...