Vergelijk 2 rijen en plaats missende cellen aan het einde rij 2

[LangeJohn]

Beste,

Om de informatie uit het ERP-Systeem bruikbaar te kunnen maken, wil ik eerst de belangrijkste informatie categoriseren en minder belangrijke info achter aan de rij toevoegen.

Ondertussen is het mij gelukt om de informatie die ik gecategoriseerd wil hebben, gecategoriseerd is in tabel 2 (sorteren data). Echter wil ik de data die mist (ofwel de data die nog niet is gecategoriseerd), toevoegen aan tabel 2.

Ik ben dus op zoek naar een formule die hetvolgende doet: Vergelijk alle waarden (A4:G4) rij 4 tabel 1 met 'gecatogorizeerde waarden (I4:L4) ' rij 4 tabel 2, voeg missende waarden toe aan rij 4 tabel 2 (startend bij kolom 'M'). Het kan voorkomen dat dit meer dan 1 waarde is, zoals het voorbeeld ook aangeeft.

Ik heb de waarden die ik uit mijn formule wil krijgen met groene achtergrond gegeven, om het nog duidelijker te maken naar waar ik op zoek ben.


Een voorbeeld document heb ik toegevoegd.

Kunnen jullie mij hiermee helpen?

Ontzettend bedankt voor het meedenken!

Bekijk bijlage voorbeeld vergelijken data.xlsx

 

[AlexCEL]

En waarop kan ik sorteren dan? M.a.w. hoe kan ik Excel laten weten dat "lengte 1" een lengte is? Ik neem dat in jouw bestand hier een getal staat o.i.d.

Ik moet iets hebben om de data in de linkertabel bij een kolom in de rechtertabel te kunnen matchen. Een afmeting, een code, een lijst met kleuren of ISO-normen. Zoiets...

 

[LangeJohn]

Moet hij per se kunnen sorteren?

De kolommen I t/m L zijn in het officiele bestand al formules die automatisch sorteren. Ik zoek puur de formule die de nog niet gesorteerde waarden uit tabel 1, toevoegd achter de gesorteerde waarden in tabel 2

Ik zoek een formule die het volgende doet:

Vergelijk uit tabel 1: A4:G4 met waarden I4:L4.... Hier ziet de formule:
A4: True (waarde A4 zit in I4:L4
B4: False (waarde B4 zit NIET in I4:L4
C4: True (waarde C4 zit in I4:L4
D4: True (waarde D4 zit in I4:L4
E4: False (waarde E4 zit NIET in I4:L4
F4: True (waarde F4 zit in I4:L4
G4: False (waarde G4 zit NIET in I4:L4

Voor de 'False' waarden (Bel 1, ISO 1002, lege cell) wil ik dat deze (achtereenvolgend, zonder lege cellen ertussen) in rij 4 kolom M,N,O komen te staan.

Opnieuw de groene cellen stelt het resultaat van de formule voor. Officieel is hij leeg en vult de formule deze cellen aan.

 

[AlexCEL]

Als je alleen de groene kolommen zoekt wordt het gemakkelijker :thumb:

Probeer deze eens:

M3: =ALS.FOUT(INDEX($A3:$G3;KLEINSTE(ALS(ISFOUT(VIND.SPEC($A3:$G3;$I3&$J3&$K3&$L3));KOLOM($A:$G);9^9);KOLOM(A1)));"")

Let op: dit is een Matrixfunctie, d.w.z. afsluiten met Control+Shift+Enter na invoeren en voor doorvoeren naar onder en naar rechts.

 

[LangeJohn]

AlexCEL,

Dankje voor de formule! Wanneer ik deze formule vertaal naar het Engels en toepas op het voorbeeld, werkt hij perfect!

Echter, wanneer ik hem probeer te gebruiken op mijn daadwerkelijke sheet krijg ik geen gegevens te zien. Wellicht kun jij zien wat ik fout doe:

Engels:
=IFERROR(INDEX($T5:$AF5,SMALL(IF(ISERR(SEARCH($T5:$AF5,$AM5&$AN5&$AO5&$AP5&$AQ5&$AR5&$AS5&$AT5&$AU5&$AV5&$AW5&$AX5)),COLUMN($T:$AF),9^9),COLUMN(T1))),"")

Nederlands
=ALS.FOUT(INDEX($T5:$AF5;KLEINSTE(ALS(ISFOUT(VIND.SPEC($T5:$AF5;$AM5&$AN5&$AO5&$AP5&$AQ5&$AR5&$AS5&$AT5&$AU5&$AV5&$AW5&$AX5));KOLOM($T:$AF);9^9);KOLOM(T1)));"")

Ik heb gespeeld met de laatste kolom(waarde): T1, A1, B1 etc. Maar dat heeft geen invloed. Daarnaast doe ik zoals je zegt: Control shift enter en selecteer ik eerst naar onder en dan naar rechts

 

[AlexCEL]

Opm:
1. COLUMN(T1) moet in elk geval worden COLUMN(A1). Dit stukje zorgt ervoor dat de SMALL functie als input k=1,2,3,4 krijgt bij doortrekken naar rechts.
2. Verander INDEX($T5:$AF5,..) eens in INDEX(5:5;...). De formule bepaalt namelijk het kolomnummer waar de gezochte waarde in staat. Als je niet op kolom A start met zoeken, zoals de INDEX functie doet, dan krijg je niet de gewenste resultaten.
3. Er ontbreekt een komma. Nu zoek je een RIJ-nummer op, terwijl het een KOLOMNUMMER moet zijn. De extra komma vertelt excel dat je alleen naar kolommen wilt kijken. Syntax is INDEX(matrix,rijnummer,kolomnummer).

Volledig formule wordt dan:

=IFERROR(INDEX([COLOR="#FF0000"]5:5[/COLOR],[COLOR="#FF0000"],[/COLOR]SMALL(IF(ISERR(SEARCH($T5:$AF5,$AM5&$AN5&$AO5&$AP5&$AQ5&$AR5&$AS5&$AT5&$AU5&$AV5&$AW5&$AX5)),COLUMN($T:$AF),9^9),COLUMN([COLOR="#FF0000"]A1[/COLOR]))),"")

Het zijn trouwens wel erg veel cellen die aan elkaar geknoopt worden in je eigen bestand. Als je beetje nieuwe versie van excel hebt dan is daar ook wel weer een functie voor om het wat overzichtelijker te maken:

=IFERROR(INDEX(5:5,,SMALL(IF(ISERROR(SEARCH($T5:$AF5,CONCAT($AM5:$AX5))),COLUMN($T:$AF),9^9),COLUMN(A1))),"")

 

[LangeJohn]

Geprobeerd en nog steeds krijg ik niets, raar dit!

 

[AlexCEL]

Probeer nogmaals s.v.p. Heb nog wijzigingen doorgevoerd na je bericht.

PS
Op basis van je formule zie ik dat je 13 kolommen hebt (T t/m AF) en reeds 12 hiervan zijn gesorteerd (AM t/m AX). Je zoekt dus eigenlijk de waarde uit de overblijvende kolom?

 

[LangeJohn]

Het is gelukt! Dankjewel!

Het is wat ingewikkelder. De ene rij met gegevens heeft gegevens X Y Z, terwijl een andere rij gegevens X A B heeft. Ik sorteer deze gegevens (T t/m AF) op een aantal criteria (AM t/m), en wanneer er gegevens zijn die niet aan de criteria voldoen, komen deze nu aan het einde van de tabel onder 'ongecategorizeerde informatie'. Het is moeilijk uit te leggen, maar de conclusie blijft hetzelfde: Het werkt en ik ben je zeer dankbaar!

 

[AlexCEL]

Als het voor jou maar werkt dan is het goed toch. :thumb:

Veel plezier ermee.