Verkenner openen

[bkoppers]

Onderstaande code gebruik ik om een bestand map te openen na het opslaan van een bestand, dit werkt prima, echter als de bepaalde map al geopend is dan opent er toch een 2 venster, weet iemand hoe ik dit moet aanpassen zodat hij de reeds geopende map selecteert.


Sub hyperlink_maken()
Range("A35").Select
ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:= _
"G:\bedrijfsbureau\" & Range("j1").Value & "\Documenten\" & Range("jaar").Value & "\" & Range("VK").Value & " - " & Range("Ordernummer").Value & "\Documenten"
Range("A35").Select
Selection.Hyperlinks(1).Follow NewWindow:=False, AddHistory:=True
End Sub

 

[MDN111]

Als ik dat zo zie wil je een folder openen waarvan de naam af te leiden is uit de inhoud van een aantal cellen. Onderstaande code werkt bij mij (Office 2003). D.w.z. als er reeds een explorer window met de betreffende folder geopend is, wordt er geen tweede meer geopend. Misschien kan je die code gebruiken mits enkele aanpassingen.

'Voor de eenvoud gaan we er van uit dat de volledige path in de cell A1 staat.
'Bijvoorbeeld C:\Users\MDN111\Documents\Reports

Sub OpenFolder()
Dim cPath As String, cTitle As String, myShell As Object

'De titel van het Explorer window is de naam van de folder.
cPath = ThisWorkbook.Sheets(1).Cells(1, 1)
cTitle = Right(cPath, Len(cPath) - InStrRev(cPath, "\"))

'De AppActivate method van de WSH opent het window met de betreffende titel,
'als dat bestaat. Als het niet bestaat openen we een nieuwe Explorer.
Set myShell = CreateObject("wscript.shell")
If Not myShell.AppActivate(cTitle) Then
    Shell "explorer.exe " & cPath, vbNormalFocus
End If
Set myShell = Nothing
End Sub

Grtz,
MDN111.

 

[snb]

Je hebt de verkenner helemaal niet nodig; waarom gebruik je niet ?

sub M_snb()
     ChDir "G:\bedrijfsbureau\" & Range("J1").Value & "\Documenten\" & Range("jaar").Value & "\" & Range("VK").Value & " - " & Range("Ordernummer").Value & "\Documenten"
    Application.GetOpenFilename "Excel files (*.xls;*.xlsm; *.xlam; *.xla), *.xls)"
End Sub

of

Sub M_snb()
    ChDir "G:\bedrijfsbureau\" & Range("J1").Value & "\Documenten\" & Range("jaar").Value & "\" & Range("VK").Value & " - " & Range("Ordernummer").Value & "\Documenten"
    Application.Dialogs(xlDialogFindFile).Show
end sub

 

[bkoppers]

Allereerst bedankt voor jullie reacties, mijn kennis van VBA is nog niet zo super goed, dus ik ben erg blij met jullie hulp.

SNB, als ik jou code gebruik kan ik een bepaald bestand openen, dat is niet wat ik wil, ik wil enkel de folder waar mijn bestand is opgeslagen openen.

MDN11 Jou code is perfect. thx

M.v.g. Bkoppers

 

[snb]

Dan heb je de code niet getest, want dat is ook het enige wat de code doet.