Verticaal zoeken combineren met Index

[BBP1]

Beste lezer,

Is het mogelijk om verticaal zoeken te combineren met de index functie?

Op blad 2 heb ik gegevens ingevuld zoals , naam, geboortedatum, adres, postcode, woonplaats.
Op blad 1 wil ik zoeken in A1 op geboortedatum.
In het voorbeeld is het gelukt om de index functie hiervoor te gebruiken maar nu wil ik graag de gegevens die horen bij de geboortedatums zichtbaar krijgen in het overzicht.

Ik hoop dat iemand mij kan helpen met mijn probleem.

 

[HSV]

Verander de INDEX(kolom;
INDEX(Blad2!A2:$A$1000;

 

[AlexCEL]

Deze voor A5, kan je naar rechts doortrekken.

=ALS.FOUT(INDEX(Blad2!A$2:A$1000;KLEINSTE(ALS(Blad2!$B$2:$B$1000=$A$1;RIJ(A$2:A$1000)-1;"x");RIJ(A1)));"")

Cel-opmaak even aanpassen naar datum en getal als je doortrekt...

Mocht je Excel 365/2021+ gebruiken kan deze ook:

=FILTER(Blad2!A2:C15;Blad2!B2:B15=A1;"")

 

[peter59]

Beetje uitgewerkt met de hint van AlexCEL v.w.b. O365/2021 versie.

 

[BBP1]

Bedankt dit is inderdaad wat ik zoek. Ik wil de gegevens op blad 2 verder uitbreiden. Maar ik snap niet zo goed hoe ik dit op blad 1 terug moet laten komen

 

[BBP1]

Verander de INDEX(kolom;
INDEX(Blad2!A2:$A$1000;

Ik ben niet zo heel erg ervaren. Kunt u dit verder uitleggen?

 

[peter59]

Dan maak je van de gegevens op Blad2, een tabel.

 

[BBP1]

Dan maak je van de gegevens op Blad2, een tabel.

Kan ik kolommen in de tabel ook verbergen/uitzetten zodat deze niet op blad 1 zichtbaar zijn?
Niet alle gegevens hoeven op blad 1 zichtbaar te zijn .

 

[peter59]

=FILTER(TblData[[Naam]:[BSN]];TblData[geb]=Blad1!A1;"datum niet bekend")

In dit stukje kan je kolommen kiezen welke je wilt zien.

TblData[[Naam]:[BSN]]

 

[peter59]

Een iets andere opzet.

=FILTER(KIEZEN({1\2\3\4\5\6}; TblData[Naam]; TblData[geb]; TblData[BSN]; TblData[adres]; TblData[postcode]; TblData[woonplaats]); TblData[geb]=Blad1!A1; "datum niet bekend")

Hier worden alle kolommen welke in de tabel voorkomen, benoemd.

(KIEZEN({1\2\3\4\5\6}

In dit stukje van de formule kan je de kolommen kiezen welke je wilt zien tevens kan je eventueel ook de volgorde ook wijzigen.

 

[HSV]

=Kies.kolommen(
Is er ook nog.

 

[peter59]

Zo, ik ook weer iets geleerd.
Gebruik deze formule n.a.v. de hint van @HSV.

=FILTER(KIES.KOLOMMEN(TblData; {1\2\3\4\5\6}); TblData[geb]=Blad1!A1; "datum niet bekend")

Veel korter én overzichtelijker.

 

[BBP1]

Ik wil jullie hartelijk bedanken voor de kennis die is overgedragen!
Het bestand is precies zoals ik het graag wil hebben.

Bedankt

 

[HSV]

@peter59,
=Kieskolommen(tbldata;1;2;3;4;5;6) etcetera.

 

[peter59]

@HSV
Dat is een goeie.
De ; werkt maar ook de \

 

[HSV]

Dat gaat hem niet worden met een \ zonder de accolades.
Hier nog een als de kolommen op volgorde zijn en je wil er bv. maar 4 zien.

=FILTER(NEMEN(TblData;;4); TblData[geb]=Blad1!A1; "datum niet bekend")

 

[peter59]

Dat gaat hem niet worden met een \ zonder de accolades.

Klopt als een bus.