Verticaal zoeken met een ALS conditie

[Smitzel]

Hi,

Ik loop tegen het volgende aan:

Ik heb een lijst met data (kolom G), waar de zoekconditie (kolom A) meerdere keren in voorkomt.
Ik wil de data uit kolom H opzoeken met verticaal zoeken zodat deze in kolom B verschijnt.
Maar omdat de zoekconditie meerdere keren voorkomt in in kolom G kan verticaal zoeken daar niet standaard mee omgaan.

Het moet er dan als volgt uit komen te zien:

Als kolom H gevuld is, gebruik die regel dan voor verticaal zoeken met de waarde uit kolom A en plaats H in B

Ik ben al geruime tijd aan het stoeien hiermee, ik hoop dat iemand mij uit de brand kan helpen!

 

[OctaFish]

Ik zou daar een draaitabelletje voor maken, en daarin opzoeken.

 

[AlexCEL]

Een optie voor B6:

=INDEX($H$4:$H$17;VERGELIJKEN(1;($G$4:$G$17=A6)*($H$4:$H$17<>"");0))

 

[Smitzel]

Een optie voor B6:

=INDEX($H$4:$H$17;VERGELIJKEN(1;($G$4:$G$17=A6)*($H$4:$H$17<>"");0))

Bedankt voor uw reactie, precies wat ik zoek! :thumb:

 

[Smitzel]

Een optie voor B6:

=INDEX($H$4:$H$17;VERGELIJKEN(1;($G$4:$G$17=A6)*($H$4:$H$17<>"");0))

Ik probeer nu een wildcard toe te voegen aan A6:

=INDEX($H$4:$H$17;MATCH(1;($G$4:$G$17="*"&A6&"*")*($H$4:$H$17<>"");0))

dit geeft echter niet het gewenste resultaat, werkt een wildcard anders bij INDEX?

 

[AlexCEL]

Klik s.v.p. ietsje lager als je wilt reageren op een bericht. Die blauwe knop is ook nog eens VEEL groter dan de quote knop. Of het gebruik het tekstvak snel reageren onderaan de pagina.

On topic: plaats s.v.p. nog een keer een voorbeeldje. Geef daarin ook eventjes het gewenste resultaat aan. Dan kunnen we wat gerichter op je vraag ingaan.

 

[Smitzel]

voorbeeld voor 2de vraag (wildcards)

Het is de bedoeling dat de formule uitgebreid wordt met een wildcard voor de zoekopdracht uit A6.
De tabel waarin gezocht wordt heeft cellen waarin de zoekopdracht staat, samen met nog andere waardes.

In de bijlage een voorbeel xlsx

 

[AlexCEL]

Iets andere oplossing:

B6: =ALS.FOUT(INDEX($H:$H;MIN(ALS(ISGETAL(VIND.SPEC($A6;$G$4:$G$17))*($H$4:$H$17<>"");RIJ($G$4:$G$17))));"")

let op: dit is een matrixfunctie, die moet je afsluiten met Control+Shift+Enter als je geen Excel 365 gebruikt.

Mocht je wel Excel 365 gebruiken kan deze ook:

=FILTER($H$4:$H$17;ISGETAL(VIND.SPEC(A6;$G$4:$G$17))*($H$4:$H$17<>"");"")

 

[Smitzel]

Zo wat gaaf zeg, dat werkt zoals ik bedoelde!

Heel erg bedankt Alex(pert) voor je hulp :thumb: Hier was ik zelfstandig nooit uitgekomen.