Vlookup voor variabele sheet EN column

[Molovhic]

Hoi allemaal

Ik heb een file met data, 12 sheet's (vernoemd naar de maanden van het jaar) + 1 sheet (genaamd DATA)
waar ik aan de hand van drop down's data wil vergaren uit de andere sheets.

Het voorbeeld dat ik nu heb is:
- Uit de eerste dropdown selecteer ik de maand
- Uit de 2de dropdown selecteer ik mijn dag (1,2,3,...)

Aan de hand van de volgende formule (die ik toevallig gevonden heb) krijg ik wel de juiste maand SHEET
maar omdat de VLOOKUP COL INDEX op 1 staat gaat hij altijd maar de eerste kolom uit de range selecteren

=VLOOKUP(D4,INDIRECT("'"&B4&"'!"&"E4:AI4"),1)

D4 is de cel waar de dropdown van de dagen staat, "'"&B4&"'!" is de dropdown cel met de maand, op basis van die maand
gaat hij naar de sheet en kijkt hij in de range E4 tot AI4 (zijn de 31 dagen telkens), tot hier gaat alles goed.
Echter de COL INDEX (1 in dit geval) is niet meer variabel.

Heb nu al het één en ander opgezocht maar kan niet direct vinden hoe ik deze variabel kan maken zodat de keuze van de "dagen" drop down list
ook een invloed heeft op het eindresultaat.

Alvast bedankt.

 

[HSV]

En als je het adres aangeeft waar de 1 staat?
Ook is je formule Vlookup niet compleet.
=Vlookup(wat,bereik,kolom,false)
of:
=Vlookup(wat,bereik,kolom,0)

[COLOR=#3E3E3E]=VLOOKUP(D4,INDIRECT("'"&B4&"'!"&"E4:AI4"),cel van dropdow2,0)[/COLOR]

Anders even een bestand plaatsen wil ook wel helpen.

 

[Molovhic]

Bekijk bijlage data.xlsx

Hoi, hierbij een getrimde versie.

Heb de Vlookup reeds aangevuld maar dit hielp niet.
Hopelijk ben je hier iets mee.

Alvast bedankt voor de moeite!

 

[HSV]

Eng.

=HLOOKUP(D4,INDIRECT("'"&B4&"'!E3:AI4"),2,0)

Ned.

=HORIZ.ZOEKEN(D4;INDIRECT("'"&B4&"'!E3:AI4");2;0)

 

[Molovhic]

Netjes! niet bij stilgestaan dat de Vlookup hier dan een hlookup zou moeten zijn

Heel erg bedankt Harry!

 

[HSV]

Het is nog niet helemaal af natuurlijk.
Zet onderstaande formule in validatielijst2.

Eng.

=OFFSET($AO$2,MATCH($B$4,$AO$3:$AO$15,0),1,1,31)

Ned.

=VERSCHUIVING($AO$2;VERGELIJKEN($B$4;$AO$3:$AO$15;0);1;1;31)

 

[Molovhic]

Done, voorlopig lijkt alles te werken, snap ook de redenering, alleen was ik er zelf nooit op kunnen komen vermits
mijn kennis beperkt is, ga dit volop testen en dan zien dat ik alle maanden eens toevoeg voor te kijken of het effectief werkt.

Laten we hopen dat we nu vertrokken zijn zonder hulp

Nogmaals bedankt

 

[HSV]

Nog mooier en beter is natuurlijk het aantal argumenten meenemen in de validatie (januari 31 dagen, februari 28).
Eng.

=OFFSET($AO$2,MATCH($B$4,$AO$3:$AO$15,0),1,1,COUNTA(OFFSET($AO$2,MATCH($B$4,$AO$3:$AO$15,0),1,1,31)))

Ned.

=VERSCHUIVING($AO$2;VERGELIJKEN($B$4;$AO$3:$AO$15;0);1;1;AANTALARG(VERSCHUIVING($AO$2;VERGELIJKEN($B$4;$AO$3:$AO$15;0);1;1;31)))

Nu hou ik er maar over op totdat er nieuwe vragen zijn natuurlijk.
Graag gedaan overigens.