Voorkomen gebruik Activate

[Symphysodon]

Ik heb een beginnersvraag.

In een stuk code wil ik de format van een bereik op een bepaald tabblad instellen, zonder eerst naar dat tabblad te gaan. Het programma is op dat moment dus op een ander tabblad.

Onderstaande code werkt alleen als ik eerst het tabblad Voorbeeld activeer.

Hoe kan ik dit nu netjes oplossen?

Set tbl = Sheets("Voorbeeld").[a3].CurrentRegion
tbl.Offset(0, 1).Resize(tbl.Rows.Count, tbl.Columns.Count - 1).Select
With Selection
    .HorizontalAlignment = xlCenter
End With
With Selection.Font
    .Name = "Arial"
    .Size = 8
    .Bold = False
End With

Mvg
Marco

 

[snb]

with Sheets("Voorbeeld").cells(1).CurrentRegion
  .HorizontalAlignment = -4108
  With .Font
    .Name = "Arial"
    .Size = 8
    .Bold = False
  End With
Edn with

 

[Symphysodon]

De selectie is niet helemaal die ik bedoelde maar mijn vraag is wel beantwoord.

Set tbl = Sheets("Voorbeeld").[a3].CurrentRegion
With tbl.Offset(0, 1).Resize(tbl.Rows.Count, tbl.CurrentRegion.Columns.Count - 1)
  .HorizontalAlignment = -4108
    With .Font
        .Name = "Arial"
        .Size = 8
        .Bold = False
    End With
End With

 

[snb]

Maar je hebt er te weinig van opgestoken.
De variabele is overbodig.

 

[Symphysodon]

De variabele wordt verder in de code nog gebruikt. Maar hoe zou ik het in dit geval dan zonder die variabele kunnen doen.
cells(1) in jou code is toch [a1]?

 

[snb]

Ik ga ervan uit dat je in een werkblad altijd cel A1 gebruikt.
Toon in een voorbeeldbestand wat je wil.

 

[Symphysodon]

In de bijlage een voorbeeld.

Een tweede vraag zou nog kunnen zijn hoe ik vanuit een geresizde current region, de tweede rij kan bewerken om er een datumnotatie van te maken.

 

[Symphysodon]

De tweede is vraag is opgelost

Sub mformat()

Set tbl = Sheets("Voorbeeld").[a3].CurrentRegion
With tbl.Offset(0, 1).Resize(tbl.Rows.Count, tbl.Columns.Count - 1)
      .HorizontalAlignment = -4108
      .Resize(1).Offset(1, 0).NumberFormat = "m/d/yyyy"
    With .Font
        .Name = "Arial"
        .Size = 8
        .Bold = False
    End With
End With


End Sub

 

[snb]

Verwijder eerst de lege rijen 1 en 2.

Dan is dit genoeg:

Sub M_snb()
    With Sheets("Voorbeeld").Cells(1).CurrentRegion
      .Rows(2).NumberFormat = "dd-mm-yyyy"
      .HorizontalAlignment = -4108
      With .Font
        .Name = "Arial"
        .Size = 8
        .Bold = False
      End With
    End With
End Sub

 

[Symphysodon]

Kan helaas niet de eerste regel is een titel regel met ander letterformat.

Bedankt voor de hulp.

 

[snb]

Probeer eerst eens de code te begrijpen voordat je reageert !
En lees eens een boek VBA voor beginners van het begin tot het einde door.

Sub M_snb()
    With Sheets("Voorbeeld").Cells(1).CurrentRegion.offset(1)
      .Rows(1).NumberFormat = "dd-mm-yyyy"
      .HorizontalAlignment = -4108
      With .Font
        .Name = "Arial"
        .Size = 8
        .Bold = False
      End With
    End With
End Sub

 

[jkpieterse]

Dit doet het ook met de tabel startend vanaf cel A3:

Sub mformat()
    With Sheets("Voorbeeld").Range("a3").CurrentRegion
        .Rows(2).NumberFormat = "dd-mm-yyyy"
        With .Offset(0, 1).Resize(.Rows.Count, .Columns.Count - 1)
            .HorizontalAlignment = xlCenter
            With .Font
                .Name = "Arial"
                .Size = 8
                .Bold = False
            End With
        End With
    End With
End Sub

Lijkt overigens erg op snb's code, vind je ook niet

 

[Symphysodon]

Bedankt