Waarde Opzoeken in meedere lijsten met gebruik van VLOOKUP of IF?

[AnnetteGerrits]

Hey Allemaal,

Ik loop op het werk tegen een probleempje aan. Ik wil graag een document nummer opzoeken in een lijst en daar dan de titel van weergeven. Dit is vrij makkelijk te doen met gebruik van de VLOOKUP (engelse excel versie) functie. Dat leverd dan de volgende formule op:

=VLOOKUP(C7;'[Reference List.xls]SOP`S'!$A3:$F6000;6;FALSE

Nu is alleen het probleem dat de waarde in C7 voor kan komen in 2 verschillende lijsten (niet in allebei tegelijk). In mijn logica moet de formule dan iets worden in de richting van:

=VLOOKUP(C7;OR('[Reference List.xls]SOP`S'!$A3:$F6000;'[Reference List.xls]SOP`S'!$A3:$F6000);6;FALSE

Uiteraard werkt dit niet! Ik heb het nu tijdelijk opgelost met een hulp kolom (met old/new om te bepalen in welke lijst te zoeken) waardoor de uiteindelijke formule op het volgende neer komt:

=IF(B8="old";VLOOKUP(C8;'[Reference List.xls]SOP`S'!$A4:$F6001;6;FALSE);VLOOKUP(C8;'[New Reference List 2015.xlsx]SOP'!$D:$K;6;FALSE))

Maar ik zou het wel heel fijn vinden als die hulp kolom niet nodig is! Weet iemand hier een oplossing voor?

Want om het uiteindelijk nog een beetje ingewikkelder te maken heb ik ook nog verschillende types documenten.
Dus 1 SOP nummer die in lijst A of B voor komt
FRM nummers die in lijst C of D voor komt
Policy Nummers die in Lijst E of F voor komt en ga zo maar door.

Op dit moment probeer ik het op te lossen met 2 hulp kolommen. waarvan 1 het document type weergeeft en de andere in welke van de 2 lijsten je moet gaan zoeken.
Nu ben ik dus opzoek naar een formule die zegt als A1 "SOP" is zoek C1 in lijst A, komt die voor in lijst A geef dan "old", komt die niet voor in lijst A geeft dan "new", maar als A1 "FRM" is zoek dan C1 in Lijst C, komt die voor in lijst C geef dan "old", komt die niet voor in lijst C geef dan "new".

Ik vermoed dat dit met een een IF (ALS) formule opgelost moet gaan worden. Maar ik kom niet verder dan:

=IF(A8="SOP";(IF(COUNTIF('[Reference List.xls]SOP`S'!$A:$A;C8);"old";"new");IF(A8="FRM";IF(COUNTIF('[Reference List.xls]FORMS'!$A:$A;C8);"old";"new").....

Maar deze formule levert mij alleen maar "#VALUE" op.

Ik hoop dat het zo een beetje duidelijk is. Ik heb een voorbeeld bestandje gemaak waar lijst A, B, C en D op apparte tabbladen zijn gezet. Het overszichts tabblad is waar uiteindelijk de formules in moeten komen!

Alvast heel erg bedankt!

 

[oeldere]

We hebben niet de beschikking over de andere excelbestand (waarin ook wordt gezocht), maar ik zou de lijsten a t/m D in 1 tabblad vermelden, dat maakt het zoeken alleen maar gemakkelijker.

 

[AlexCEL]

In bijlage een voorstel voor een oplossing zonder hulpkolommen e.d.

Bekijk bijlage example (AC).xlsx

 

[AnnetteGerrits]

Hoi Oeldere,

i.v.m. gevoelige informatie mag en kan ik andere bestand waarin word gezocht niet vrijgeven. Ik heb de gegevens van deze lijst gemimicked in de losse tabbladen (lijst A en C komt overeen met "reference lijst", lijst B en D met "new reference list"). Als ik alle lijsten bij elkaar zou kunnen voegen zou het zoeken zoiezo oneindig veel makkelijker worden, dan is het gauw opgelost met een een VLOOKUP functie. Helaas is dit niet mogelijk en zal ik toch in de 4 (of 6 of 8 of 10) lijsten moeten blijven werken.

Ik hoop dat ik het zo iets opgehelderd heb.

Alvast Bedankt,
met vriendelijk groet,
Annette Gerrits

 

[AlexCEL]

Deze moet voldoen (NL):

=ALS.FOUT(VERT.ZOEKEN(A7;'Lijst A'!A:B;2;0);ALS.FOUT(VERT.ZOEKEN(A7;'Lijst B'!A:B;2;0);ALS.FOUT(VERT.ZOEKEN(A7;'Lijst C'!A:B;2;0);ALS.FOUT(VERT.ZOEKEN(A7;'Lijst D'!A:B;2;0);"onbekend nummer"))))

Engelse vertaling (volgens deze site: http://en.excel-translator.de/translator/)

=IFERROR(VLOOKUP(A7,'Lijst A'!A:B,2,0),IFERROR(VLOOKUP(A7,'Lijst B'!A:B,2,0),IFERROR(VLOOKUP(A7,'Lijst C'!A:B,2,0),IFERROR(VLOOKUP(A7,'Lijst D'!A:B,2,0),"onbekend nummer"))))

Naar behoefte uit te breiden...

Aangepast voorbeeldje: Bekijk bijlage example (AC).xlsx

 

[AnnetteGerrits]

Ja! dat is het, super bedankt!!!

De engelse vertaling werkt perfect, dat zijn de formules inderdaad.
Ik was dus eigenlijk gewoon veeeeeel te moeilijk aan t denken!

Nogmaals heel erg bedankt, ik zal de vraag op opgelost zetten!

met vriendelijk groet,
Annette Gerrits

 

[snb]

of

=SUMPRODUCT((LijstA!A:A=A7)+(LijstB!A:A=A7)+(LijstC!A:A=A7)+(LijstD!A:A=A7))>0

 

[AlexCEL]

Hey snb ... hier komt toch geen titel uitrollen dat bij het documentnummer hoort? Deze checkt m.i. alleen of het nummer bestaat.

 

[snb]

@AlxL

Dat klopt helemaal.