• Privacywetgeving
    Het is bij Helpmij.nl niet toegestaan om persoonsgegevens in een voorbeeld te plaatsen. Alle voorbeelden die persoonsgegevens bevatten zullen zonder opgaaf van reden verwijderd worden. In de vraag zal specifiek vermeld moeten worden dat het om fictieve namen gaat.

waarden zoeken

Status
Niet open voor verdere reacties.

Wim0000

Gebruiker
Lid geworden
17 apr 2020
Berichten
12
Beste,

Op het tabblad dagplanning had ik graag telkens aan de hand van cel C2 (datum vandaag) voor elke persoon uit kolom B de bijhorende dienst voor die dag verkregen uit het tabblad "uurrooster 2022" . Kan iemand mij op weg helpen aub? Alvast bedankt!
 

Bijlagen

zo?

PHP:
=INDEX('Uurrooster 2022 (2)'!$E$2:$SO$6;VERGELIJKEN(B3;'Uurrooster 2022 (2)'!$D$2:$D$6;0);VERGELIJKEN($C$2;'Uurrooster 2022 (2)'!$D$2:$SO$2;0))
 
bedankt!

Dag SjonR

Eerst en vooral bedankt voor uw snelle reactie! Als ik onderstaande formule plak in cel C3 van het tabblad "Dagplanning" plak krijg ik het resultaat WP64. Dit zou in principe de waarde uit de cel EJ4 van het tabblad "uurrooster 2022 (2)" moeten zijn. Misschien was mijn vraag niet helemaal duidelijk of doe ik iets verkeerd. Wil je de formule nog eens herbekijken aub? Alvast bedankt!
 
Laatst bewerkt:
Probeer deze eens

Code:
=LET(r;'Uurrooster 2022 (2)'!$D$2:$SO$6;INDEX(r;MATCH($B3;INDEX(r;;1);0);MATCH($C$2;CHOOSEROWS(r;1);0)))

Of als je geen office 365 hebt een kleine aanpassing in de eerder geplaatste formule

Code:
=INDEX('Uurrooster 2022 (2)'!$D$2:$SO$6;MATCH(B3;'Uurrooster 2022 (2)'!$D$2:$D$6;0);MATCH($C$2;'Uurrooster 2022 (2)'!$D$2:$SO$2;0))
 
Laatst bewerkt:
Volgens mij moet het deze formule zijn:

Code:
=INDEX('Uurrooster 2022 (2)'!$F$4:$SO$6;VERGELIJKEN(B3;'Uurrooster 2022 (2)'!$D$4:$D$6;0);VERGELIJKEN($C$2;'Uurrooster 2022 (2)'!$F$2:$SO$2;0))
 
Laatst bewerkt:
Ook:
Code:
=XLOOKUP(B3,'Uurrooster 2022 (2)'!D$4:D$6,XLOOKUP(C$2,'Uurrooster 2022 (2)'!F$2:SO$2,'Uurrooster 2022 (2)'!F$4:SO$6))
Code:
=X.ZOEKEN(B3;'Uurrooster 2022 (2)'!D$4:D$6;X.ZOEKEN(C$2;'Uurrooster 2022 (2)'!F$2:SO$2;'Uurrooster 2022 (2)'!F$4:SO$6))

Of:
Code:
=FILTER(FILTER('Uurrooster 2022 (2)'!F$4:SO$6;'Uurrooster 2022 (2)'!F$2:SO$2=C$2);'Uurrooster 2022 (2)'!D$4:D$6=B3)

En als de namen in dezelfde volgorde staan kan het met:
Code:
=FILTER('Uurrooster 2022 (2)'!F4:SO6;'Uurrooster 2022 (2)'!F2:SO2=C2)
 
Laatst bewerkt:
Bedankt allemaal, er zijn blijkbaar meerdere oplossingen. Ik heb uiteindelijk deze van popipipo gebruikt en verder uitgewerkt naar het volledig document. Werkt perfect!! Hartelijk dank voor de hulp!!!
 
Status
Niet open voor verdere reacties.
Terug
Bovenaan Onderaan