week rooster

[ronnie123]

beste forum leden
hoe pak ik het volgende het beste aan?
ik wil een week planning maken, heb in B1 het jaartal staan.
nu ben ik begonnen met in a4 =datum(B1;1;2) is maandag 2 januari maar als ik er 2013 van maak in B1 begint de week op woensdag en dat moet niet.
weet iemand een betere manier?
groetjes ronnie

 

[pasan]

mischien heb je hier wat aan

 

[ronnie123]

hallo pasan
bedankt voor de snelle reactie ga dit eens bestuderen je hoort van me
groetjes ronnie

 

[Niels28]

Een formule die waarschijnlijk een stuk korter kan om de datum van maandag week 1 te berekenen als het jaartal in cel b1 staat.

=ALS((DATUM($B$1;1;1)-WEEKDAG(DATUM($B$1;1;1);2)+ALS(WEEKDAG(DATUM($B$1;1;1);2)<5;1;8))-DATUM(JAAR(DATUM($B$1;1;1)-WEEKDAG(DATUM($B$1;1;1);2)+ALS(WEEKDAG(DATUM($B$1;1;1);2)<5;1;8));1;0)>8;DATUM(($B$1-1);1;1)+(DATUM($B$1;1;1)-WEEKDAG(DATUM($B$1;1;1);2)+ALS(WEEKDAG(DATUM($B$1;1;1);2)<5;1;8))-DATUM(JAAR(DATUM($B$1;1;1)-WEEKDAG(DATUM($B$1;1;1);2)+ALS(WEEKDAG(DATUM($B$1;1;1);2)<5;1;8));1;0)-1;DATUM(($B$1);1;1)+(DATUM($B$1;1;1)-WEEKDAG(DATUM($B$1;1;1);2)+ALS(WEEKDAG(DATUM($B$1;1;1);2)<5;1;8))-DATUM(JAAR(DATUM($B$1;1;1)-WEEKDAG(DATUM($B$1;1;1);2)+ALS(WEEKDAG(DATUM($B$1;1;1);2)<5;1;8));1;0)-1)

Niels

 

[ronnie123]

hallo Niels
ook bedankt voor de snelle reactie!
werkt perfect heb je mischien ook nog wat voor de week nummers want die gaan nu fout
groetjes ronnie

 

[Niels28]

welke excel versie?

Niels

 

[ronnie123]

2007
grt ronnie

 

[Niels28]

Met datum in B2

=INTEGER((B2-DATUM(JAAR(B2+4-WEEKDAG(B2+6));1;5)+WEEKDAG(DATUM(JAAR(B2+4-WEEKDAG(B2+6));1;3)))/7)+1

ps de formule in vorige post iets verkleind.

voor excel2010 gebruikers

=WEEKNUMMER(B2;21)

Niels

 

[ronnie123]

Niels bedankt het werkt kan nu mooi door bouwen :thumb:
groetjes ronnie

 

[Niels28]

Dag Ronnie,

formule voor maandag week 1 flink ingekort

=ALS(WEEKDAG(DATUM($B$1;1;1);2)<5;DATUM($B$1;1;1)-WEEKDAG(DATUM($B$1;1;1);2)+1;DATUM($B$1;1;1)+8-WEEKDAG(DATUM($B$1;1;1);2))

Niels

 

[popipipo]

Nog ietjes korter:

=(DATE($B1;1;3)-WEEKDAY(DATE($B1;1;3)))+2

 

[robdgr]

Kijk eens op www.schoutsen.nl voor diverse datumfuncties.