weeknummers voorzien van jaartal

[Kessy]

Hallo allemaal,

Ik gebruik de onderstaande formule om van een datum automatisch het weeknummer te laten berekenen, maar nu wil ik er ook graag de laatste 2 cijfers van het jaartal voor hebben staan.
bv. week 1 van 2010 wordt dan 1001, week 1 van 2009, 0901 etc.

=INTEGER((A2-DATUM(JAAR(A2-WEEKDAG(A2-1)+4);1;3)+WEEKDAG(DATUM(JAAR(A2-WEEKDAG(A2-1)+4);1;3))+5)/7)

Wie kan me daarbij helpen?

bedankt!

een blonde dame

 

[Thoralf]

Hallo Blonde dame,

Wat dacht je van:

=TEKST(JAAR(A2);"jj")&INTEGER((A2-DATUM(JAAR(A2-WEEKDAG(A2-1)+4);1;3)+WEEKDAG(DATUM(JAAR(A2-WEEKDAG(A2-1)+4);1;3))+5)/7)

 

[Kessy]

oke, dat werkt, maar ik krijg bij de datum 01-01-2010 het weeknummer 0553 ipv 0953.
ik krijg altijd 05 bij elke datum in 2010..

groeten Kessy

 

[Warme bakkertje]

=rechts(jaar(a2);2)&integer((a2-datum(jaar(a2-weekdag(a2-1)+4);1;3)+weekdag(datum(jaar(a2-weekdag(a2-1)+4);1;3))+5)/7)

 

[Thoralf]

Hallo Kessy,

Ik heb 2 denkfoutjes begaan:
Allereerst moet het begin aangepast worden naar:
=TEKST(A2;"jj")&INTEGER
dus de verwijzing naar de JAAR-functie eruit.
Het tweede foutje zit hem in de keuze van de waarde voor het bepalen van het jaartal.
Wil je dit correct doen dan moet de eerste verwijzing naar A2 gewijzigd worden naar de maandag van de week waarin A2 valt. Dit lost het probleem op dat er kan ontstaan in de eer
ste of laatste week van het jaar.
Dit betekent een aanpassing van het beginstuk tot
=TEKST(A2-WEEKDAG(A2;2)+1;"jj")&INTEGER

Aanvulling:
En om ook de laatste foutjes er uit te halen moet de formule worden:

=TEKST(A2-WEEKDAG(A2;2)+1;"jj")&TEKST(INTEGER((A2-DATUM(JAAR(A2-WEEKDAG(A2-1)+4);1;3)+WEEKDAG(DATUM(JAAR(A2-WEEKDAG(A2-1)+4);1;3))+5)/7);"00")

 

[Kessy]

Bedankt!

Thanks Thoralf en Rudi!

idd, met de formule van rudi kwam ik op de fouten bij het begin en einde van het jaar omdat excel het getal 2010 ziet als een datum in 1905..

met de laatste formule van Thoralf ben ik er!

Super bedankt voor alle hulp!