weeknummers

[rostie-rostelli]

Hallo,

Hoe kan ik naast een datumveld waar dagelijks de datum veranderd ook automatisch het weeknummer laten verschijnen?

vriendelijke groeten,
Danny

 

[Thankyou]

Deze A1 is de datum:

=INTEGER((A1-DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;3)+WEEKDAG(DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;3))+5)/7)

of deze:

=GEHEEL((A1-WEEKDAG(A1;2)+4-DATUM( JAAR(A1-WEEKDAG(A1;2)+4) ; 1 ; 1))/7)+1

of deze via een UDF:

Public Function ISOweeknum(ByVal Datum As Date) As Integer

ISOweeknum = DatePart("ww", Datum + 4 - Weekday(Datum, 2), 2, 2)

End Function

de formule in de cel is dan =ISOweeknum(A1)

Succes,

 

[rostie-rostelli]

Thankyou, thank you voor de reactie, maar spijtig genoeg heb ik een engelstalige versie van 2003 (niet mijn fout maar mijn werkgever hoor ! )en ik vrees dat deze geen Nederlandstalige formules begrijpt !! tenzij misschien de UDF formule, maar waar definieer ik de cel waar het weeknummer moet in terecht komen aub?

Alvast bedankt !!
Danny

 

[popipipo]

http://www.applewood.nl/forms/3000/FRM-004/

Zie hier voor vertaling van formules.

 

[edmoor]

=WEEKNUMMER(NU())

Of een cel met een datum in plaats van NU()

 

[Thankyou]

De site om formules te vertalen staat in mijn handtekening.

=INT((A1-DATE(YEAR(A1-WEEKDAY(A1-1)+4),1,3)+WEEKDAY(DATE(YEAR(A1-WEEKDAY(A1-1)+4),1,3))+5)/7)

en

=TRUNC((A1-WEEKDAY(A1,2)+4-DATE( YEAR(A1-WEEKDAY(A1,2)+4), 1, 1))/7)+1

De UDF is zeg maar een eigen gemaakte (in dit geval: geleende) formule. de formule die je voor deze UDF dient te gebruiken is :

=ISOweeknum(A1)

en die stond ook al in mijn eerste bericht.

Hoop dat je nu verder kunt.
Succes,

 

[Thankyou]

@ Edmoor,
Dit geeft aan dat we nu in week 53 leven . . . ??
Volgens de geldende normen in Nederland/Belgie is dit echter week 52.
Daarnaast werkt die functie pas vanaf excel 2007, en de TS heeft niet aangegeven met welke versie hij werkt.

 

[edmoor]

Ja, dat is inderdaad een bekend probleem van de standaard weeknummer functie.

 

[rostie-rostelli]

Hallo,

De formule van "thankyou" werkt perfect in "excel 2003" we zijn vandaag in week 52, en dit is denk ik correct! enkel in de formule een kleine aanpassing moeten doen, de "," moeten ";" zijn

=TRUNC((A1-WEEKDAY(A1,2)+4-DATE( YEAR(A1-WEEKDAY(A1,2)+4), 1, 1))/7)+1
moet dus
=TRUNC((A2-WEEKDAY(A2;2)+4-DATE( YEAR(A2-WEEKDAY(A2;2)+4); 1; 1))/7)+1
zijn.

Hartelijk bedankt Thankyou en Edmoor voor de oplossing en moeite :thumb:

Groetjes,
Danny

 

[Thankyou]

enkel in de formule een kleine aanpassing moeten doen, de "," moeten ";" zijn

Dit hangt af van de instellingen die in excel zijn gedaan.

Bedankt voor het op opgelost/afgehandeld zetten.

Groet,