Werkbalken

[Jorre]

Hello,

Ik zou mijn programma dat ik gemaakt heb in Excel op een eenvoudige wijze willen beschermen door telkens wanneer het programma gestart wordt direct naar de beeldmodus "volledig scherm" te gaan, door een password in te geven kan je dan terug naar het gewone beeldscherm. Enige probleem is dat in de volledige modus nog steeds de "werkbladmenubalk" staat (die met bestand,beeld,...) en daar kan je dan ook de volledige modus afzetten, niet zo goed dus

Bon wanneer je nu in excell op werbalken klikt en dan naar aanpassen gaat kan je het vinkje van "werkbladmenubalk" af zetten, en je ziet de balk dan ook verdwijnen, enige minpuntje is dat wanneer je daarna op sluiten drukt en het pop-up venstertje verdwijnt de balk gewoon terug verschijnt.

Heeft iemand een oplossing om de bovenste balk weg te houden? mss is het forceerbaar met een VB programmaatje?

grts
en alvast bedankt

Jorre

 

[arafy]

jorre,

als je toolbar intikt bij zoeken vind je o.a. dit

steven

 

[CorVerm]

Jorre,
Misschien vind je hier wat je zoekt.

 

[Jorre]

Nop, voor zover ik het begrijp is dat om de basisinstellingen terug te zetten, omdat die blijkbaar aangepast worden naarmate je bepaalde knoppen meer gebruikt dan andere, maar daarmee kan ik nog niet mijn bovenste werkbalk laten verdwijnen.

Ofwel ben stekeblind en stom en heb ik het niet zien staan

nog ideeen

Jorre

 

[CorVerm]

Dan kun je hier kijken op de site van Luc H. Excel> Lessen>Manipuleer Excel.
Zoals Luc ook aangeeft: Liever niet doen.

 

[Hof1607]

Re Werkbalken verbergen

Beste Jorre

ik weet niet waarom je het niet moet gebruiken maar hier is code waarmee dat kan

Application.CommandBars("Formatting").Visible = False
Application.CommandBars("Standard").Visible = False
Application.CommandBars("Visual Basic").Visible = False
Application.CommandBars("Worksheet Menu Bar").Enabled = False

gebruik dus op eigen risico

Suc6 Willem

 

[jpvs]

Bestand FullScreen openen.

Zet onderstaande code in ThisWorkbook:

Dim SkipEvent As Boolean 

Private Sub Workbook_Activate() 
    If SkipEvent Then 
        SkipEvent = Not SkipEvent 
        Exit Sub 
    End If 
    OpslaanVerbergenMenus 
End Sub 

Private Sub Workbook_Deactivate() 
    If SkipEvent Then Exit Sub 
    HerstelLatenZienMenus 
End Sub 

Private Sub Workbook_Open() 
    SkipEvent = True 
    OpslaanVerbergenMenus 
End Sub 

Private Sub Workbook_BeforeClose(Cancel As Boolean) 
    SkipEvent = True 
    HerstelLatenZienMenus 
    DoEvents 
End Sub 

Private Sub Workbook_SheetActivate(ByVal Sh As Object) 
    If Sh.Name <> "NoFullScreen" Then 
        Application.DisplayFullScreen = True 
    Else 
        Application.DisplayFullScreen = False 
    End If 
End Sub

En onderstaande code in een gewone Module:

Dim cb As CommandBar, f As Integer, cbName As String, Props(5) As Long 

Sub OpslaanVerbergenMenus() 
f = FreeFile 
Open ActiveWorkbook.Path & "/MenuData.txt" For Output As #f 
For Each cb In ThisWorkbook.Application.CommandBars 
    'Om alleen menubars die je ziet te verbergen, verander het dan naar cb.Visible 
    If cb.Enabled Then 
        Write #f, cb.Name, cb.Top, cb.Left, cb.Height, cb.Width, cb.Position 
        cb.Enabled = False 
    End If 
Next 
Close #f 
AnderenLatenZien False 
End Sub 

Sub HerstelLatenZienMenus() 
    On Error Resume Next 
    f = FreeFile 
    Open ActiveWorkbook.Path & "/MenuData.txt" For Input As #f 
    Do Until EOF(f) 
        Input #f, cbName, Props(1), Props(2), Props(3), Props(4), Props(5) 
        With ThisWorkbook.Application.CommandBars(cbName) 
            .Enabled = True 
            .Top = Props(1) 
            .Left = Props(2) 
            .Height = Props(3) 
            .Width = Props(4) 
            .Position = Props(5) 
        End With 
    Loop 
    Close #f 
    Kill ActiveWorkbook.Path & "/MenuData.txt" 
    AnderenLatenZien True 
End Sub 

Sub AnderenLatenZien(HideStuff As Boolean) 
    Application.WindowState = xlMaximized 
    With ActiveWindow 
        .DisplayGridlines = HideStuff 
        .DisplayHeadings = HideStuff 
        .DisplayOutline = HideStuff 
        .DisplayZeros = HideStuff 
        .DisplayHorizontalScrollBar = HideStuff 
        .DisplayVerticalScrollBar = HideStuff 
        .DisplayWorkbookTabs = HideStuff 
    End With 
    With Application 
        .DisplayFormulaBar = HideStuff 
        .DisplayStatusBar = HideStuff 
        .ShowWindowsInTaskbar = HideStuff 
    End With 
End Sub

code is van Oele van Dishoeck


Loop er iets mis?
Ga naar de site van Luc H. http://www.newbytes.be/
Klik op Excel
Ga naar Downloads en zie Nr2
"Instellingen herstellen"

Geknoeid in Excel? Uw werkbalken verdwenen? De snelmenu van uw rechtermuisknop heeft te veel menuonderdelen gekregen? Dit is de oplossing!

Pierre

 

[Jorre]

Bedankt

Bedankt allemaal voor de respons, ik ben ook eens op luc zijn site gaan kijken en zo tot een goeie oplossing voor het probleem gekomen.

in open workbook :

Application.DisplayFullScreen = True
Dim i As Integer
For i = 1 To Application.CommandBars.Count
Application.CommandBars(i).Enabled = False
Next


en in before close :

Dim i As Integer
For i = 1 To Application.CommandBars.Count
Application.CommandBars(i).Enabled = True

Next

voila mss kan iemand anders er ook nog iets mee doen

grts

Jorre

 

[arafy]

jorre,

tof dat je de oplossing geeft. misschien kan je in het vervolg de code wel tussen codetags plaatsen. dat leest gemakkelijker. zie ook deze tip