willekeurige foto's aanklikken bij een rapport

[Markos169]

ik heb even een vraagje en hoop dat iemand voor mij een programmacode heeft aangezien ik daar niet zo goed in ben

ik moet voor me werk een rapport uit kunnen printen, waarbij er op het voorblad een foto moet komen van de opdrachtgever. dit rapport is een standaard rapport, dus ik moet wel elke keer een andere foto er op aan kunnen klikken. kan iemand mij helpen? en wat voor knop moet ik op het voorblad plaatsen? de foto's komen uit een map weg waar ik ze daarna zelf aan kan klikken en dat ik de foto dan gepresenteerd zie op het voorblad.

ik heb al gezocht in de database maar kon niet dit probleem vinden. ik hoop dat iemand mij kan helpen.

alvast bedankt
Mark

 

[OctaFish]

Een foto op een rapport is een redelijk vast gegeven: je zet een kader op je voorblad, en kiest daar een foto voor. Je kunt denk ik geen knop op een rapport zetten (misschien wel in 2007?) waarmee je kunt wisselen.
Wel kun je, op het formulier van waaruit je het rapport opent, bijvoorbeeld een knop maken waarmee je een foto selecteert, die dan wordt toegewezen aan het Image object op het rapport.

Met onderstaande functie kun je een foto selecteren:

Function KiesFoto()
On Error GoTo err_cmdInsertImage_Click
'De bibliotheek <<Microsoft Office 12 Office Library>> moet geladen zijn, anders een foutmelding

Dim dlgPicker As FileDialog
Dim strFileName As String
Dim strPath As String
Dim strFile As String

'Eerst de variabelen leegmaken
strPath = ""
strFileName = ""

'Open de Windows bestandenlijst, met als argument het type
Set dlgPicker = Application.FileDialog(msoFileDialogFilePicker)

With dlgPicker
.Title = "Selecteer een foto." 'De titel voor het venster
'Pas dit aan voor map met afbeeldingen
.InitialFileName = CurrentProject.Path 'Waar moet het venster beginnen?
.Filters.Add "JPG", "*.jpg", 1 'Beperk de bestandstypes tot .jpg, en maak dat het eerste item in de lijst
.AllowMultiSelect = False 'Slechts één bestand kiezen toegestaan
'' .InitialView = msoFileDialogViewPreview ' Weergave met Preview
.InitialView = msoFileDialogViewList ' Weergave Lijst

If .Show = -1 Then 'Bepaal of gebruiker op OK-knop heeft geklikt.
strFileName = .SelectedItems.Item(1) 'String wordt gevuld met geselecteerde bestand
End If
End With

KiesFoto = strFileName

Exit Function
'====================================================================================================================

err_cmdInsertImage_Click:
Select Case Err.Number
Case 75 'De gebruiker klikt op de knop Annuleren.
MsgBox "U hebt geen foto geselecteerd.", vbOKOnly + vbInformation, "Melding"
Case Else 'Overige gevallen
MsgBox "Fout in: " & "cmdInsertImage_Click, foutnummer:" & Err.Number & ", " & Err.Description
End Select

End Function

Met bijgaande code die je op een knop kunt hangen, zet je het plaatje op het rapport:

Private Sub cmdFoto_Click()
Dim stDocName As String, sFoto As String

    sFoto = KiesFoto
    stDocName = "Rapport"
    DoCmd.OpenReport stDocName, acViewDesign, , , acHidden
    Reports(stDocName).Report!picVoorpagina.Picture = sFoto
    DoCmd.Close acReport, stDocName, acSaveYes
    DoCmd.OpenReport stDocName, acViewPreview

End Sub

Succes!

 

[Markos169]

Bedankt octafish ik zal het even proberen en hoop dat ik eruit kan komen.

als er nog vragen zijn dan hoor je van me.

groeten mark