Zoek en vervang maar ook in formules (macro)

[Muiter]

Hier een stukje van de macro die ik gebruik:

    Cells.Replace What:="#verw", Replacement:="'herinneringen overzicht'", _
        LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:= _
        False, ReplaceFormat:=False

Helaas zoek ik hiermee niet in formules, hoe kan ik dit wel doen?

 

[snb]

zie
voorkom foutmeldingen

 

[Wigi]

Ik heb code voor jou geschreven:

Sub FindAllRefErrors()
    
    Dim rAllRefErrors As Range
    
    Set rAllRefErrors = AllRefErrors(Columns("C:C"))
    
    If Not rAllRefErrors Is Nothing Then
        rAllRefErrors.Select
    Else
        MsgBox "No REF errors found", vbInformation, "Output"
    End If

End Sub

Function AllRefErrors(r As Range) As Range
    
    Dim rTemp As Range
    Dim rTemp2 As Range
    Dim rng As Range
    Dim CellValue As Variant
    
    On Error Resume Next
    Set rTemp = r.SpecialCells(xlCellTypeFormulas, xlErrors)
    On Error GoTo 0
    
    If rTemp Is Nothing Then
        
        Set AllRefErrors = Nothing
        Exit Function
    
    Else
        
        For Each rng In rTemp
            
            CellValue = rng.Value
            
            If CellValue = CVErr(xlErrRef) Then
            
                If rTemp2 Is Nothing Then
                
                    Set rTemp2 = rng
                
                Else
                
                    Set rTemp2 = Application.Union(rTemp2, rng)
                    
                End If
            
            End If
            
        Next
        
    End If
    
    Set AllRefErrors = rTemp2
    
End Function

De eerste procedure moet je uitvoeren, en tevens een passende range geven voor AllRefErrors.

Wigi

 

[Wigi]

Trouwens, deze code had je kunnen vinden met de zoekfunctie van het forum.

http://www.helpmij.nl/forum/showthread.php?t=356934