zoeken naar

[ArthurvH]

Goedemorgen,

Ik ben op zoek naar een formule die de namen van 1 bepaalde groep achter elkaar zet.

Stel ik heb 20 mensen en deze moeten verdeeld worden in 5 groepen.
Alleen de namen van de mensen veranderen steeds en in welke groep ze zitten ook.

Dus eigenlijk zoals dit:

de namen
Ben 1
Andre 2
Carla 3
Simon 2
Pieter 1
Tim 2
Luke 3

in groep 1 Ben,Pieter
in groep 2 Andre,Simon,Tim
in groep 3 Carla,Luke

dan wil ik dat als ik een 1 achter Ben zet. Dat ben z'n naam automatisch in groep 1 komt eigenlijk zoal ik hierboven heb voorgedaan.

Is zoiets mogelijk?

 

[peter59]

Bedoel je zo iets?
Dit is gedaan met power query.

 

[AlexCEL]

Wellicht zoiets voor Excel 365:

="In groep 1: "&TEKST.COMBINEREN(", ";1;FILTER(A1:A7;B1:B7=1;""))

 

[AlexCEL]

Of deze, kun je doortrekken naar behoefte (Excel 365):

=LET(g;RIJ(A1);"In groep "&g&": "&TEKST.COMBINEREN(", ";1;FILTER(A$2:A$8;B$2:B$8=g;"")))

 

[snb]

gewoon sorteren op groep.

 

[HSV]

Ineens voor een kolom.

=LET(a;UNIEK(B2:B8);"In groep "&a&": "&MAP(a;LAMBDA(x;TEKST.COMBINEREN(", ";;FILTER(A2:A8;B2:B8=x)))))

Of voor twee kolommen.

=LET(a;UNIEK(B2:B8);KIEZEN({1\2};"In groep "&a&":";MAP(a;LAMBDA(x;TEKST.COMBINEREN(", ";;FILTER(A2:A8;B2:B8=x))))))

In het voorbeeldbestand van @AlexCEL

 

[HSV]

Deze formule kan je er ook nog aan toevoegen (mooi kort).

=GROEPEREN.PER("In groep "&B2:B8&":";A2:A8;ARRAYTOTEXT;;0)