lege cellen verwijderen op meerdere tabbladen tegelijk

[don42]

beste allemaal,

ik heb een werkboekje waarvan ik uit de tabbladen die genummerd zijn met 1 t/m 53 de lege cellen wil verwijderen
met:

Private Sub CommandButton1_Click()
'If ActiveSheet.Name <= 53 Then
Range("b3:h40").Select
Selection.SpecialCells(xlCellTypeBlanks).Select
    Selection.Delete Shift:=xlUp
    Range("B4").Select
End Sub

lukt het prima per sheet
Wie weet hoe het moet om dit te klaren op alle tabbladen tegelijk

don

 

[edmoor]

Zoiets:

Private Sub CommandButton1_Click()
    For Each sht In ThisWorkbook.Sheets
        Select Case sht.Name
            Case 1 To 53
                sht.Range("B3:H40").SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
        End Select
    Next sht
End Sub

 

[SjonR]

zo?

Private Sub CommandButton1_Click()
For i = 1 To 53
    Sheets(CStr(i)).Range("b3:h40").SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
Next
End Sub

 

[don42]

Private Sub CommandButton1_Click()
For Each sht In ThisWorkbook.Sheets
        Select Case sht.Name
            Case 1 To 53
                'fout melding sht.Range("B3:H40").SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
        End Select
    Next sht
End Sub

 

[edmoor]

Werkt hier prima.
Het is nooit handig om te zeggen dat je een foutmelding krijgt zonder deze er bij te vermelden.
Die zijn er niet om gebruikers te pesten.

Probeer anders die van SjonR.

 

[don42]

Private Sub CommandButton1_Click()
For i = 1 To 53
'fout melding > Sheets(CStr(i)).Range("b3:h40").SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
Next
End Sub

 

[don42]

gaat ook niet goed,

waar doe ik wat verkeerd?

 

[edmoor]

En de tweede regel uit m'n vorige reactie heb je niet gelezen?
Plaats een voorbeeld document.

 

[don42]

Heb snel even een voorbeeld document gemaakt
en daar werkt het prima, helaas niet in mijn bestandje
maar ik zie als ik met rechts op een tabblad klik dat er veel opties grijs zijn
bv de tab kleur of verwijderen sheet is niet mogelijk
zou dat er iets mee te maken hebben?

In elk geval de code die jullie gemaakt hebben werken perfect.
iemand een idee hoe het kan dat er sommige opties bij rechtsklik op een tab grijs blijven (niet beschikbaar)

 

[edmoor]

Je doet nog steeds niet wat gevraagd is en waarmee de oorzaak van je probleem opgespoord kan worden.
Succes.

 

[don42]

dat bestandje = 4.6 mb groot
krijg ik niet verstuurd

 

[edmoor]

Lees nog eens regel 2 in #5.

 

[don42]

Fout 1004

Er zijn geen cellen gevonden

 

[Ginger]

Specialcells komt volgens mij in een error terecht als de gevraagde voorwaarde niet wordt gevonden... Ik gok dat hier een Error afhandeling omheen moet.

 

[edmoor]

Precies:

Private Sub CommandButton1_Click()
    On Local Error Resume Next
    For Each sht In ThisWorkbook.Sheets
        Select Case sht.Name
            Case 1 To 53
                sht.Range("B3:H40").SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
        End Select
    Next sht
    On Local Error GoTo 0
End Sub

 

[Ginger]

Fout 1004

Er zijn geen cellen gevonden

En had ik dus gelijk...

 

[edmoor]

En daarom is het vermelden van zo'n foutmelding dus belangrijk.

Nu kan het ook nog zo zijn dat het blad beveiligd is, of dat er _Change events actief zijn die roet in het eten gooien.
Dan werkt het nog steeds niet maar zie je geen foutmelding.
Dan kan je dit doen:

Private Sub CommandButton1_Click()
    On Local Error GoTo Foutje
    For Each sht In ThisWorkbook.Sheets
        Select Case sht.Name
            Case 1 To 53
                sht.Range("B3:H40").SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
        End Select
    Next sht
    On Local Error GoTo 0
    Exit Sub

Foutje:
    If Err.Number = 1004 Then
        Resume Next
    Else
        MsgBox Err.Description
        Exit Sub
    End If
End Sub

 

[don42]

:d

Heren ik ben blij dat jullie onderling er nog een leuke competitie aan vastknopen
dit was idd de oplossing
Edmoor sorry ik had niet meteen door dat je deze melding nodig had voor de oplossing
maar ben blij met jullie hulp
dank jullie
fijn weekend

 

[edmoor]

Hetzelfde gewenst

 

[SjonR]

met een voorbeeldbestandje had dit draadje een stuk korter kunnen zijn

Fijn weekend.