macro voor verschillende werkbladen

[Theophiel]

hallo beste forumleden,

Graag had ik wat hulp gehad voor een macro die voor bepaalde (niet alle) werkbladen zou moeten dienen.

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

    If (Target.Column = 16) Then
        ActiveCell.Interior.ColorIndex = 36
        Range("B3") = ActiveCell.Value
    ElseIf (Target.Column = 17) Then
        ActiveCell.Interior.ColorIndex = 36
        Range("H3") = ActiveCell.Value
    End If
End Sub

Ik geraak er niet uit.

Alvast bedankt op voorhand!

 

[SjonR]

Dient het nu wel voor alle werkbladen dan? Deze code staat toch in een specifiek werkblad?

 

[Theophiel]

Bedankt voor je reactie,

Nu dient de macro voor 1 bepaald werkblad, maar zou hem graag gebruiken voor meerdere bladen, maar zeker niet voor alle bladen.

mvg

 

[SjonR]

dan zet je het toch in elk werkblad waar je het wilt gebruiken!

 

[edmoor]

Deze in de ThisWorkbook sectie:

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
    Dim Kol As String
    Select Case Sh.Name
        Case "Blad1", "Blad3"
            Select Case Target.Column
                Case 16:    Kol = "B"
                Case 17:    Kol = "H"
            End Select
            If Kol <> "" Then
                Target.Interior.ColorIndex = 36
                Range(Kol & "3") = Target.Value
            End If
    End Select
End Sub

 

[VenA]

of

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
If Sh.Name = "Sheet1" Or Sh.Name = "Sheet2" Then Exit Sub
  If Target.Column = 16 Or Target.Column = 17 Then
    Target.Interior.ColorIndex = 36
    Cells(3, 2).Offset(, -(Target.Column = 17) * 7) = Target.Value
    Cancel = -1
  End If
End Sub

 

[Theophiel]

Hartelijk dank voor de snelle reacties!

Ik heb uiteindelijk de keuze van edmoor gekozen, maar toch beide bedankt.

mvg

 

[snb]

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
  If instr("Sheet1Sheet2",Sh.Name) or Target.Column <16 or Target.Column >17 Then Exit sub

  Target.Interior.ColorIndex = 36
  sh.Cells(3, 2+6*(target.column-16)) = Target.Value
  Cancel = -1
End Sub