Weeknummer met toevoeging 0

[Aigisthos]

Hallo allen,

Ik heb een vraag ik zou graag een ISO weeknummer notatie willen maar dan weeknummers 1 t/m 9 met een 0 ervoor.

=JAAR(A1)&"-"&INTEGER((A1-DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;3)+WEEKDAG(DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;3))+5)/7)

Bovenstaande formule gebruik ik nu en dan is de notatie bv 2010-2

Dit zou ik verandert willen hebben naar 2010-02.

Heb een groot deel van Internet nagezocht maar het is me niet duidelijk hoe ik dit voor elkaar krijg.

Misschien kunnen jullie helpen.

Alvast bedankt,

Aigisthos

 

[Wigi]

De functie TEKST kan een getal als 5 omzetten naar 05. Bvb. =TEKST(5,"00")

 

[HSV]

Opmaak aangepast:
jjjj-mm


Sorry, gaat om weeknummer, verkeerd gelezen.

 

[Aigisthos]

De functie TEKST kan een getal als 5 omzetten naar 05. Bvb. =TEKST(5,"00")

Hoe zet ik dit in bovenstaande formule dan als ik mag vragen??

 

[HSV]

Zo had Wim het in gedachten.

=JAAR(A1)&"-"&TEKST(INTEGER((A1-DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;3)+WEEKDAG(DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;3))+5)/7);"00")

Ik weet niet of Wim nog online is, vandaar.

 

[Wigi]

Hetgeen dat de 2 als resultaat oplevert, komt in plaats van de 5.

Daarachter komt de ;"00")

Het eerste deel blijft onaangeroerd.

Wigi

 

[Aigisthos]

Zo had Wim het in gedachten.

=JAAR(A1)&"-"&TEKST(INTEGER((A1-DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;3)+WEEKDAG(DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;3))+5)/7);"00")

Ik weet niet of Wim nog online is, vandaar.

Helemaal goed wist niet dat het zoiets kleins was!

Heel erg bedankt beide!:thumb:

 

[Wigi]

Dan graag nog de vraag als opgelost markeren aub :thumb:

 

[snb]

En nu met een simpeler isoweekformule

=JAAR(A1) & "-" & TEKST(GEHEEL((A1-WEEKDAG(A1;2)+4-DATUM(JAAR(A1-WEEKDAG(A1;2)+4);1;1))/7)+1;"00")

 

[Aigisthos]

En nu met een simpeler isoweekformule

=JAAR(A1) & "-" & TEKST(GEHEEL((A1-WEEKDAG(A1;2)+4-DATUM(JAAR(A1-WEEKDAG(A1;2)+4);1;1))/7)+1;"00")

Thanks hij is zeker simpeler